Contract Source Code:

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: Unlicensed
pragma solidity 0.8.20;

interface ILootCreator {

    struct MultiCreate {
        // Address of the Distributor handling the Quest rewards
        address distributor;
        // ID of the Quest
        uint256 questId;
        // Timestamp of the period
        uint256 period;
    }

	function getBudgetForPeriod(uint256 period) external view returns(uint256 palAmount, uint256 extraAmount);
	function getGaugeBudgetForPeriod(
        address gauge,
        uint256 period
    ) external view returns(uint256 palAmount, uint256 extraAmount);
	function getQuestAllocationForPeriod(
        uint256 questId,
        address distributor,
        uint256 period
    ) external view returns(uint256 palPerVote, uint256 extraPerVote);

	function getListedDistributors() external view returns(address[] memory);

	function createLoot(address user, address distributor, uint256 questId, uint256 period) external;
	function createMultipleLoot(address user, MultiCreate[] calldata params) external;

	function notifyQuestClaim(address user, uint256 questId, uint256 period, uint256 claimedAmount) external;
	function notifyDistributedQuestPeriod(uint256 questId, uint256 period, uint256 totalRewards) external;
    function notifyAddedRewardsQuestPeriod(uint256 questId, uint256 period, uint256 addedRewards) external;
	function notifyUndistributedRewards(uint256 palAmount) external;
	function notifyNewBudget(uint256 palAmount, uint256 extraAmount) external;

	function updatePeriod() external;
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.20;

library Errors {
    
    // Commons
    error AddressZero();
    error NullAmount();
    error InvalidParameter();
    error SameAddress();
    error ArraySizeMismatch();
    error AlreadyInitialized();

    // Access Control
    error CannotBeOwner();
    error CallerNotPendingOwner();
    error CallerNotAllowed();

    // Merkle Distributor
    error EmptyParameters();
    error InvalidProof();
    error AlreadyClaimed();
    error MerkleRootNotUpdated();
    error EmptyMerkleRoot();
    error IncorrectQuestID();
    error QuestAlreadyListed();
    error QuestNotListed();
    error PeriodAlreadyUpdated();
    error PeriodNotClosed();
    error IncorrectPeriod();
    error PeriodNotListed();
    error TokenNotWhitelisted();
    error IncorrectRewardAmount();
    error CannotRecoverToken();

    // HolyPalPower
    error InvalidTimestamp();

    // Vote Controller
    error AlreadyListed();
    error LockExpired();
    error VotingPowerInvalid();
    error VotingPowerExceeded();
    error VotingPowerProxyExceeded();
    error VotingCooldown();
    error KilledGauge();
    error NotKilledGauge();
    error NotAllowedManager();
    error NotAllowedProxyVoter();
    error ExpiredProxy();
    error ProxyAlreadyActive();
    error ProxyPowerExceeded();
    error ProxyDurationExceeded();
    error NotAllowedVoteChange();
    error MaxVoteListExceeded();
    error MaxProxyListExceeded();
    error InvalidGaugeCap();

    // Loot
    error CreatorAlreadySet();
    error InvalidId(uint256 id);
    error VestingNotStarted(uint256 id);

    // Loot Creator
    error NotListed();

    // Loot Buget
    error LootBudgetExceedLimit();

    //Maths
    error ConversionOverflow();
}

//██████╗  █████╗ ██╗      █████╗ ██████╗ ██╗███╗   ██╗
//██╔══██╗██╔══██╗██║     ██╔══██╗██╔══██╗██║████╗  ██║
//██████╔╝███████║██║     ███████║██║  ██║██║██╔██╗ ██║
//██╔═══╝ ██╔══██║██║     ██╔══██║██║  ██║██║██║╚██╗██║
//██║     ██║  ██║███████╗██║  ██║██████╔╝██║██║ ╚████║
//╚═╝     ╚═╝  ╚═╝╚══════╝╚═╝  ╚═╝╚═════╝ ╚═╝╚═╝  ╚═══╝
 

//SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.20;

import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import {ReentrancyGuard} from "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import {ILootCreator} from "./interfaces/ILootCreator.sol";
import "./libraries/Errors.sol";
import "./utils/Owner.sol";

/** @title Loot contract */
/// @author Paladin
/*
    Contract handling the Loot data, vesting & distribution
*/

contract Loot is Owner, ReentrancyGuard {
    using SafeERC20 for IERC20;


    // Structs

    /** @notice Loot Data strcut */
    struct LootData {
        // ID of the Loot for the user
        uint256 id;
        // Amount of PAL to be distributed through vesting
        uint256 palAmount;
        // Amount of extra token to be distributed
        uint256 extraAmount;
        // Timestamp at which the vesting starts
        uint256 startTs;
        // Timestamp at which the vesting starts
        uint256 endTs;
        // Flag to check if the Loot has been claimed
        bool claimed;
    }


    // Storage

    /** @notice PAL token */
    IERC20 public immutable pal;
    /** @notice Extra reward token */
    IERC20 public immutable extraToken;

    /** @notice Address of the Reserve contract holding token to be distributed */
    address public immutable tokenReserve;
    /** @notice Loot Creator contract */
    ILootCreator public lootCreator;

    /** @notice Duration of vesting for Loots */
    uint256 public vestingDuration;

    /** @notice List of Loot for each user */
    mapping(address => LootData[]) public userLoots;


    // Events

    /** @notice Event emitted when a Loot is created */
    event LootCreated(address indexed user, uint256 indexed id, uint256 palAmount, uint256 extraAmount, uint256 startTs);

    /** @notice Event emitted when a Loot is claimed */
    event LootClaimed(address indexed user, uint256 indexed id, uint256 palAmount, uint256 extraAmount);

    /** @notice Event emitted when the vesting duration is updated */
    event VestingDurationUpdated(uint256 oldDuration, uint256 newDuration);
    /** @notice Event emitted when the Loot Creator address is updated */
    event LootCreatorUpdated(address oldCreator, address newCreator);


    // Modifiers

    /** @notice Checks the caller is the allowed Loot Creator */
    modifier onlyLootCreator() {
        if(msg.sender != address(lootCreator)) revert Errors.CallerNotAllowed();
        _;
    }


    // Constructor

    constructor(
        address _pal,
        address _extraToken,
        address _tokenReserve,
        uint256 _vestingDuration
    ){
        if(
            _pal == address(0)
            || _extraToken == address(0)
            || _tokenReserve == address(0)
        ) revert Errors.AddressZero();

        pal = IERC20(_pal);
        extraToken = IERC20(_extraToken);
        tokenReserve = _tokenReserve;
        vestingDuration = _vestingDuration;
    }

    /**
    * @notice Sets the Loot Creator contract address
    * @dev Sets the inital Loot Creator contract address
    * @param _lootCreator Address of the Loot Creator contract
    */
    function setInitialLootCreator(address _lootCreator) external onlyOwner {
        if(address(lootCreator) != address(0)) revert Errors.CreatorAlreadySet();
        lootCreator = ILootCreator(_lootCreator);
    }


    // View functions

    /**
    * @notice Returns the data of a Loot for a user & an id
    * @dev Returns the data of a Loot for a user & an id
    * @param user Address of the user
    * @param id ID of the Loot
    * @return palAmount (uint256) : Amount of PAL
    * @return extraAmount (uint256) : Amount of extra token
    * @return startTs (uint256) : Timestamp at which the vesting starts
    * @return endTs (uint256) : Timestamp at which the vesting ends
    * @return claimed (uint256) : Is Loot already claimed
    */
    function getLootData(address user, uint256 id) external view returns(
        uint256 palAmount,
        uint256 extraAmount,
        uint256 startTs,
        uint256 endTs,
        bool claimed
    ){
        LootData memory loot = userLoots[user][id];
        palAmount = loot.palAmount;
        extraAmount = loot.extraAmount;
        startTs = loot.startTs;
        endTs = loot.endTs;
        claimed = loot.claimed;
    }

    /**
    * @notice Returns all the user Loot IDs
    * @dev Returns all the user Loot IDs
    * @param user Address of the user
    * @return uint256[] : List of Loot IDs
    */
    function getAllUserLootIds(address user) external view returns(uint256[] memory){
        uint256 length = userLoots[user].length;
        uint256[] memory ids = new uint256[](length);

        for(uint256 i; i < length;){
            ids[i] = userLoots[user][i].id;
            unchecked { i++; }
        }

        return ids;
    }

    /**
    * @notice Returns all the user active Loot IDs
    * @dev Returns all the user active Loot IDs
    * @param user Address of the user
    * @return uint256[] : List of active Loot IDs
    */
    function getAllActiveUserLootIds(address user) external view returns(uint256[] memory){
        LootData[] memory _loots = userLoots[user];
        uint256 length = _loots.length;
        uint256 activeCount;

        for(uint256 i; i < length;){
            if(!_loots[i].claimed) activeCount++;
            unchecked { i++; }
        }

        // Reduce the array to the actual active Loot size
        uint256[] memory ids = new uint256[](activeCount);
        uint256 j;
        for(uint256 i; i < length;){
            if(!_loots[i].claimed) {
                ids[j] = _loots[i].id;
                unchecked { j++; }
            }
            unchecked { i++; }
        }

        return ids;        
    }

    /**
    * @notice Returns all the user Loots
    * @dev Returns all the user Loots
    * @param user Address of the user
    * @return LootData[] : List of Loots
    */
    function getAllUserLoot(address user) external view returns(LootData[] memory){
        return userLoots[user];
    }

    /**
    * @notice Returns all the user active Loots
    * @dev Returns all the user active Loots
    * @param user Address of the user
    * @return LootData[] : List of active Loots
    */
    function getAllActiveUserLoot(address user) external view returns(LootData[] memory){
        LootData[] memory _loots = userLoots[user];
        uint256 length = _loots.length;
        uint256 activeCount;

        for(uint256 i; i < length;){
            if(!_loots[i].claimed) activeCount++;
            unchecked { i++; }
        }

        // Reduce the array to the actual active Loot size
        LootData[] memory loots = new LootData[](activeCount);
        uint256 j;
        for(uint256 i; i < length;){
            if(!_loots[i].claimed) {
                loots[j] = _loots[i];
                unchecked { j++; }
            }
            unchecked { i++; }
        }

        return loots;
    }


    // State-changing functions

    /**
    * @notice Creates a new Loot for a user
    * @dev Creates a new Loot for a user
    * @param user Address of the user
    * @param startTs Timestamp at which the vesting starts
    * @param palAmount Amount of PAL
    * @param extraAmount Amount of extra token
    */
    function createLoot(address user, uint256 startTs, uint256 palAmount, uint256 extraAmount) external onlyLootCreator returns(int256) {
        if(palAmount == 0 && extraAmount == 0) return -1;

        uint256 lootId = userLoots[user].length;

        // Write the Loot parameters based on inputs
        userLoots[user].push(LootData({
            id: lootId,
            palAmount: palAmount,
            extraAmount: extraAmount,
            startTs: startTs,
            endTs: startTs + vestingDuration,
            claimed: false
        }));

        emit LootCreated(user, lootId, palAmount, extraAmount, startTs);

        return int256(lootId);
    }

    /**
    * @notice Claims a Loot for a user
    * @dev Claims a Loot for a user & slashes the PAL amount if the vesting isn't over
    * @param id ID of the Loot
    * @param receiver Address to receive the PAL & extra token
    */
    function claimLoot(uint256 id, address receiver) external nonReentrant {
        if(id >= userLoots[msg.sender].length) revert Errors.InvalidId(id);
        if(receiver == address(0)) revert Errors.AddressZero();
        // Load the Loot state
        LootData storage loot = userLoots[msg.sender][id];

        if(loot.claimed) revert Errors.AlreadyClaimed();
        if(block.timestamp < loot.startTs) revert Errors.VestingNotStarted(id);
        loot.claimed = true;

        

        uint256 palAmount = loot.palAmount;
        if(palAmount > 0) {
            // Check if the Loot is still vesting, and slash the PAL amount if needed
            if(block.timestamp < loot.endTs){
                uint256 remainingVesting = loot.endTs - block.timestamp;
                uint256 slashingAmount = palAmount * remainingVesting / vestingDuration;

                // Notify the LootCreator of the slashed amount
                lootCreator.notifyUndistributedRewards(slashingAmount);

                palAmount -= slashingAmount;
            }
            // Transfer the PAL to the receiver
            pal.safeTransferFrom(tokenReserve, receiver, palAmount);
        }
        uint256 extraAmount = loot.extraAmount;
        if(extraAmount > 0) {
        // Transfer the extra token to the receiver
            extraToken.safeTransferFrom(tokenReserve, receiver, extraAmount);
        }

        emit LootClaimed(msg.sender, id, palAmount, extraAmount);
    }

    /**
    * @notice Claims multiple Loots for a user
    * @dev Claims multiple Loots for a user & slashes the PAL amounts if the vesting isn't over
    * @param ids List of Loot IDs
    * @param receiver Address to receive the PAL & extra token
    */
    function claimMultipleLoot(uint256[] calldata ids, address receiver) external nonReentrant {
        if(receiver == address(0)) revert Errors.AddressZero();
        uint256 length = ids.length;
        uint256 totalPalAmount;
        uint256 totalExtraAmount;

        for(uint256 i; i < length;){
            if(ids[i] >= userLoots[msg.sender].length) revert Errors.InvalidId(ids[i]);
            // Load the Loot state
            LootData storage loot = userLoots[msg.sender][ids[i]];

            if(loot.claimed) revert Errors.AlreadyClaimed();
            if(block.timestamp < loot.startTs) revert Errors.VestingNotStarted(ids[i]);
            loot.claimed = true;

            // Check if the Loot is still vesting, and slash the PAL amount if needed
            uint256 palAmount = loot.palAmount;
            uint256 extraAmount = loot.extraAmount;
            if(palAmount > 0) {
                if(block.timestamp < loot.endTs){
                    uint256 remainingVesting = loot.endTs - block.timestamp;
                    uint256 slashingAmount = palAmount * remainingVesting / vestingDuration;

                    // Notify the LootCreator of the slashed amount
                    lootCreator.notifyUndistributedRewards(slashingAmount);

                    palAmount -= slashingAmount;
                }
            }

            // Sum up all the PAL & extra token to be transferred
            totalPalAmount += palAmount;
            totalExtraAmount += extraAmount;

            emit LootClaimed(msg.sender, ids[i], palAmount, extraAmount);

            unchecked { i++; }
        }

        // Transfer the PAL & extra token to the receiver
        if(totalPalAmount > 0) {
            pal.safeTransferFrom(tokenReserve, receiver, totalPalAmount);
        }
        if(totalExtraAmount > 0) {
            extraToken.safeTransferFrom(tokenReserve, receiver, totalExtraAmount);
        }
    }


    // Admin functions

    /**
    * @notice Updates the vesting duration for Loots
    * @dev Updates the vesting duration for Loots
    * @param _vestingDuration New vesting duration
    */
    function updateVestingDuration(uint256 _vestingDuration) external onlyOwner {
        if(_vestingDuration < 1 weeks) revert Errors.InvalidParameter();

        uint256 oldDuration = vestingDuration;
        vestingDuration = _vestingDuration;

        emit VestingDurationUpdated(oldDuration, _vestingDuration);
    }

    /**
    * @notice Updates the Loot Creator contract address
    * @dev Updates the Loot Creator contract address
    * @param _lootCreator Address of the new Loot Creator contract
    */
    function updateLootCreator(address _lootCreator) external onlyOwner {
        if(_lootCreator == address(0)) revert Errors.InvalidParameter();

        address oldCreator = address(lootCreator);
        if(_lootCreator == oldCreator) revert Errors.SameAddress();
        
        lootCreator = ILootCreator(_lootCreator);

        emit LootCreatorUpdated(oldCreator, _lootCreator);
    }

}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.20;

import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import "../libraries/Errors.sol";

/** @title 2-step Ownership  */
/// @author Paladin
/*
    Extends OZ Ownable contract to add 2-step ownership transfer
*/

contract Owner is Ownable {

    address public pendingOwner;

    event NewPendingOwner(address indexed previousPendingOwner, address indexed newPendingOwner);

    constructor() Ownable(msg.sender) {}

    function transferOwnership(address newOwner) public override virtual onlyOwner {
        if(newOwner == address(0)) revert Errors.AddressZero();
        if(newOwner == owner()) revert Errors.CannotBeOwner();
        address oldPendingOwner = pendingOwner;

        pendingOwner = newOwner;

        emit NewPendingOwner(oldPendingOwner, newOwner);
    }

    function acceptOwnership() public virtual {
        if(msg.sender != pendingOwner) revert Errors.CallerNotPendingOwner();
        address newOwner = pendingOwner;
        _transferOwnership(pendingOwner);
        pendingOwner = address(0);

        emit NewPendingOwner(newOwner, address(0));
    }

}