Contract Source Code:

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/AccessControl.sol)

pragma solidity ^0.8.0;

import "./IAccessControl.sol";
import "../utils/Context.sol";
import "../utils/Strings.sol";
import "../utils/introspection/ERC165.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```solidity
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
abstract contract AccessControl is Context, IAccessControl, ERC165 {
    struct RoleData {
        mapping(address => bool) members;
        bytes32 adminRole;
    }

    mapping(bytes32 => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with a standardized message including the required role.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     *
     * _Available since v4.1._
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual override returns (bool) {
        return _roles[role].members[account];
    }

    /**
     * @dev Revert with a standard message if `_msgSender()` is missing `role`.
     * Overriding this function changes the behavior of the {onlyRole} modifier.
     *
     * Format of the revert message is described in {_checkRole}.
     *
     * _Available since v4.6._
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Revert with a standard message if `account` is missing `role`.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert(
                string(
                    abi.encodePacked(
                        "AccessControl: account ",
                        Strings.toHexString(account),
                        " is missing role ",
                        Strings.toHexString(uint256(role), 32)
                    )
                )
            );
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual override returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address account) public virtual override {
        require(account == _msgSender(), "AccessControl: can only renounce roles for self");

        _revokeRole(role, account);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event. Note that unlike {grantRole}, this function doesn't perform any
     * checks on the calling account.
     *
     * May emit a {RoleGranted} event.
     *
     * [WARNING]
     * ====
     * This function should only be called from the constructor when setting
     * up the initial roles for the system.
     *
     * Using this function in any other way is effectively circumventing the admin
     * system imposed by {AccessControl}.
     * ====
     *
     * NOTE: This function is deprecated in favor of {_grantRole}.
     */
    function _setupRole(bytes32 role, address account) internal virtual {
        _grantRole(role, account);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual {
        if (!hasRole(role, account)) {
            _roles[role].members[account] = true;
            emit RoleGranted(role, account, _msgSender());
        }
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual {
        if (hasRole(role, account)) {
            _roles[role].members[account] = false;
            emit RoleRevoked(role, account, _msgSender());
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/IAccessControl.sol)

pragma solidity ^0.8.0;

/**
 * @dev External interface of AccessControl declared to support ERC165 detection.
 */
interface IAccessControl {
    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     *
     * _Available since v3.1._
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call, an admin role
     * bearer except when using {AccessControl-_setupRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     */
    function renounceRole(bytes32 role, address account) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        require(!paused(), "Pausable: paused");
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        require(paused(), "Pausable: not paused");
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1, "Math: mulDiv overflow");

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result << 3) < value ? 1 : 0);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/SignedMath.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard signed math utilities missing in the Solidity language.
 */
library SignedMath {
    /**
     * @dev Returns the largest of two signed numbers.
     */
    function max(int256 a, int256 b) internal pure returns (int256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two signed numbers.
     */
    function min(int256 a, int256 b) internal pure returns (int256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two signed numbers without overflow.
     * The result is rounded towards zero.
     */
    function average(int256 a, int256 b) internal pure returns (int256) {
        // Formula from the book "Hacker's Delight"
        int256 x = (a & b) + ((a ^ b) >> 1);
        return x + (int256(uint256(x) >> 255) & (a ^ b));
    }

    /**
     * @dev Returns the absolute unsigned value of a signed value.
     */
    function abs(int256 n) internal pure returns (uint256) {
        unchecked {
            // must be unchecked in order to support `n = type(int256).min`
            return uint256(n >= 0 ? n : -n);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Strings.sol)

pragma solidity ^0.8.0;

import "./math/Math.sol";
import "./math/SignedMath.sol";

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = Math.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `int256` to its ASCII `string` decimal representation.
     */
    function toString(int256 value) internal pure returns (string memory) {
        return string(abi.encodePacked(value < 0 ? "-" : "", toString(SignedMath.abs(value))));
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, Math.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }

    /**
     * @dev Returns true if the two strings are equal.
     */
    function equal(string memory a, string memory b) internal pure returns (bool) {
        return keccak256(bytes(a)) == keccak256(bytes(b));
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity >=0.8.19 <=0.8.20;

interface IBaseAdapter {
    /// @notice Struct used by the adapter to relay messages
    struct BridgedMessage {
        bytes message;
        address originController;
        address destController;
    }

    /// @param destChainId The destination chain ID.
    /// @param destination The destination address.
    /// @param options Additional options to be used by the adapter.
    /// @param message The message data to be relayed.
    /// @return transferId The transfer ID of the relayed message.
    function relayMessage(
        uint256 destChainId,
        address destination,
        bytes memory options,
        bytes calldata message
    ) external payable returns (bytes32 transferId);

    /// @param chainId The chain ID to check.
    /// @return bool True if the chain ID is supported, false otherwise.
    function isChainIdSupported(uint256 chainId) external view returns (bool);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.19;

import {ReentrancyGuard} from "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import {Context} from "@openzeppelin/contracts/utils/Context.sol";
import {BaseAssetBridge} from "./BaseAssetBridge.sol";
import {IBaseAdapter} from "./adapters/interfaces/IBaseAdapter.sol";
import {IController} from "./interfaces/IController.sol";
import {IFeeCollector} from "./interfaces/IFeeCollector.sol";
import {SafeERC20, IERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";

/**
 * @title AssetController
 * @notice This contract is responsible for managing the minting and burning of a specified token across different chains, using a single or multiple bridge adapters.
 */
contract AssetController is Context, BaseAssetBridge, ReentrancyGuard, IController {
    using SafeERC20 for IERC20;

    /// @notice Event emitted when the token unwrapping setting is changed.
    event AllowTokenUnwrappingSet(bool allowUnwrapping);

    /// @notice Event emitted when an asset mint message is sent to another chain.
    /// @param transferId The unique identifier of the transfer.
    /// @param destChainId The destination chain ID.
    /// @param threshold The number of bridges required to relay the asset.
    /// @param sender The address of the sender.
    /// @param recipient The address of the recipient.
    /// @param amount The amount of the asset.
    event TransferCreated(
        bytes32 indexed transferId,
        uint256 indexed destChainId,
        uint256 threshold,
        address indexed sender,
        address recipient,
        uint256 amount,
        bool unwrap
    );

    /// @notice Event emitted when a transfer can now be executed.
    /// @param transferId The unique identifier of the transfer.
    event TransferExecutable(bytes32 indexed transferId);

    /// @notice Event emitted when an asset is minted on the current chain.
    /// @param transferId The unique identifier of the transfer.
    event TransferExecuted(bytes32 indexed transferId);

    /// @notice Event emitted when transfers to a specific chain are paused or unpaused.
    event TransfersPausedToChain(uint256 indexed chainId, bool paused);

    /// @notice Event emitted when a transfer is resent.
    /// @param transferId The unique identifier of the transfer.
    event TransferResent(bytes32 indexed transferId);

    /// @notice Event emitted when an asset mint message is sent to another chain via a bridgeAdapter.
    /// @param transferId The unique identifier of the transfer.
    /// @param bridgeAdapter The address of the bridge adapter.
    event TransferRelayed(bytes32 indexed transferId, address bridgeAdapter);

    /// @notice Event emitted when an asset is received from another chain.
    /// @param transferId The unique identifier of the transfer.
    /// @param originChainId The chain id of the origin chain.
    /// @param bridgeAdapter The address of the bridge adapter that sent the message.
    event TransferReceived(bytes32 indexed transferId, uint256 originChainId, address bridgeAdapter);

    /// @notice Event emitted when the minimum number of bridges required to relay an asset for multi-bridge transfers is set.
    /// @param minBridges The minimum number of bridges required.
    event MinBridgesSet(uint256 minBridges);

    /// @notice Event emitted when bridge adapters that can be used for multi-bridge transfers, bypassing the limits have been set
    /// @param adapter The address of the bridge adapter.
    /// @param enabled The status of the adapter.
    event MultiBridgeAdapterSet(address indexed adapter, bool enabled);

    /// @notice Event emitted when the controller address for a chain is set.
    /// @param controller The address of the controller.
    /// @param chainId The chain ID.
    event ControllerForChainSet(address indexed controller, uint256 chainId);

    /// @notice Error thrown when an asset controller is not deployed/supported on the other chain
    error Controller_Chain_Not_Supported();

    /// @notice Error thrown when a multibridge adapter specified is not whitelisted
    error Controller_AdapterNotSupported();

    /// @notice Error thrown when a transfer is not executable
    error Controller_TransferNotExecutable();

    /// @notice Error thrown when the transferId is not recognized
    error Controller_UnknownTransfer();

    /// @notice Error thrown when multi-bridge transfers are disabled
    error Controller_MultiBridgeTransfersDisabled();

    /// @notice Error thrown when the threshold is not met for execution
    error Controller_ThresholdNotMet();

    /// @notice Error thrown when the msg.value and the sum of fees[] don't match
    error Controller_FeesSumMismatch();

    /// @notice Error thrown when the adapter is a duplicate in the adapters array
    error Controller_DuplicateAdapter();

    /// @notice Error thrown when the ether transfer fails
    error Controller_EtherTransferFailed();

    /// @notice Error thrown when the amount passed is zero
    error Controller_ZeroAmount();

    /// @notice Error thrown when an adapter resends a transfer that has already been delivered
    error Controller_TransferResentByAadapter();

    /// @notice Error thrown when transfers to the destination chain are paused
    error Controller_TransfersPausedToDestination();

    /// @notice Error thrown when the mint function call on the token fails
    error Controller_TokenMintFailed();

    /// @notice Error thrown when the burn function call on the token fails
    error Controller_TokenBurnFailed();

    /// @notice Struct representing a bridged asset.
    /// @dev This struct holds the details of a message to be relayed to another chain.
    struct Transfer {
        address recipient;
        uint256 amount;
        bool unwrap;
        uint256 threshold;
        bytes32 transferId;
    }

    /// @notice Struct representing a received transfer.
    /// @dev This struct holds the details of a message received from another chain.
    struct ReceivedTransfer {
        address recipient;
        uint256 amount;
        bool unwrap;
        uint256 receivedSoFar;
        uint256 threshold;
        uint256 originChainId;
        bool executed;
    }

    /// @dev The fee collector contract address.
    IFeeCollector public immutable feeCollector;

    /// @dev The local token address that is being bridged.
    address public token;

    /// @dev Allow XERC20 incoming token transfers to be unwrapped into the native token using the lockbox.
    bool public allowTokenUnwrapping;

    /// @notice The function selector for the burn(uint256) function on the token.
    bytes4 public constant BURN_SELECTOR_SINGLE = bytes4(keccak256(bytes("burn(uint256)"))); // 0x42966c68

    /// @notice The function selector for the mint function on the token.
    bytes4 public immutable MINT_SELECTOR;

    /// @notice The function selector for the burn function on the token.
    bytes4 public immutable BURN_SELECTOR;

    /// @dev The minimum number of bridges required to relay an asset for multi-bridge transfers.
    uint256 public minBridges;

    /// @notice Nonce used in transferId calculation, increments after each calculation.
    uint256 public nonce;

    /// @dev Mapping of chain IDs to their respective controller addresses. This contract knows all the controllers in supported chains.
    mapping(uint256 => address) private _controllerForChain;

    /// @dev Mapping of whitelisted bridge adapters that can be used for multi-bridge transfers. Used for both sending and receiving messages.
    mapping(address => bool) public multiBridgeAdapters;

    /// @dev Indicates whether transfers to a given chain ID are currently paused
    mapping(uint256 => bool) public transfersPausedTo;

    /// @dev Mapping of transfer id to received messages
    mapping(bytes32 => ReceivedTransfer) public receivedTransfers;

    /// @dev Mapping of transfers identified by their transfer ID.
    mapping(bytes32 => Transfer) public relayedTransfers;

    /// @dev Mapping of transfer ID to destination chain ID.
    mapping(bytes32 => uint256) public destChainForMessage;

    /// @dev Mapping of transfer ID to the bridge adapter that has delivered the transfer.
    mapping(bytes32 => mapping(address => bool)) public deliveredBy;

    /* ========== CONSTRUCTOR ========== */

    /**
     * @notice Initializes the contract with the given parameters.
     * @notice To configure multibridge limits, use the zero address as a bridge in `_bridges` and set the limits accordingly.
     * @param _addresses An array with four elements, containing the token address, the user that gets DEFAULT_ADMIN_ROLE and PAUSE_ROLE, the user getting only PAUSE_ROLE,
     *          the fee collector contract, the controller address in other chains for the given chain IDs (if deployed with create3).
     * @param _duration The duration it takes for the limits to fully replenish.
     * @param _minBridges The minimum number of bridges required to relay an asset for multi-bridge transfers. Setting to 0 will disable multi-bridge transfers.
     * @param _multiBridgeAdapters The addresses of the initial bridge adapters that can be used for multi-bridge transfers, bypassing the limits.
     * @param _chainId The list of chain IDs to set the controller addresses for.
     * @param _bridges The list of bridge adapter addresses that have limits set for minting and burning.
     * @param _mintingLimits The list of minting limits for the bridge adapters. It must correspond to the mint() function of the token, otherwise tokens cannot be minted
     * @param _burningLimits The list of burning limits for the bridge adapters. It must correspond to the burn() function of the token, otherwise tokens cannot be burned
     * @param _selectors Bytes4 array of mint and burn function selectors.
     */
    constructor(
        address[5] memory _addresses, //token, initialOwner, pauser, feeCollector, controllerAddress
        uint256 _duration,
        uint256 _minBridges,
        address[] memory _multiBridgeAdapters,
        uint256[] memory _chainId,
        address[] memory _bridges,
        uint256[] memory _mintingLimits,
        uint256[] memory _burningLimits,
        bytes4[2] memory _selectors
    ) BaseAssetBridge(_addresses[1], _addresses[2], _duration, _bridges, _mintingLimits, _burningLimits) {
        if ((_addresses[0] == address(0)) || (_addresses[3] == address(0))) revert Controller_Invalid_Params();
        token = _addresses[0];
        feeCollector = IFeeCollector(_addresses[3]);
        minBridges = _minBridges;
        emit MinBridgesSet(_minBridges);
        if (_multiBridgeAdapters.length > 0) {
            for (uint256 i = 0; i < _multiBridgeAdapters.length; i++) {
                multiBridgeAdapters[_multiBridgeAdapters[i]] = true;
                emit MultiBridgeAdapterSet(_multiBridgeAdapters[i], true);
            }
        }

        if (_addresses[4] != address(0)) {
            for (uint256 i = 0; i < _chainId.length; i++) {
                _controllerForChain[_chainId[i]] = _addresses[4];
                emit ControllerForChainSet(_addresses[4], _chainId[i]);
            }
        }
        allowTokenUnwrapping = false;
        emit AllowTokenUnwrappingSet(false);

        MINT_SELECTOR = _selectors[0];
        BURN_SELECTOR = _selectors[1];
    }

    /* ========== PUBLIC ========== */

    /**
     * @notice Sends a message to another chain via a bridgeAdapter to mint the asset.
     * @dev msg.value should contain the bridge adapter fee
     * @param recipient The address of the recipient. Could be the same as msg.sender.
     * @param amount The amount of the asset to mint.
     * @param unwrap Applicable only to XERC20 transfers. Used to unwrap the native asset using the lockbox on destination, if enabled on the destination.
     * @param destChainId The destination chain ID.
     * @param bridgeAdapter The address of the bridge adapter.
     * @param bridgeOptions Additional params to be used by the adapter.
     */
    function transferTo(
        address recipient,
        uint256 amount,
        bool unwrap,
        uint256 destChainId,
        address bridgeAdapter,
        bytes memory bridgeOptions
    ) public payable nonReentrant whenNotPaused {
        if (amount == 0) revert Controller_ZeroAmount();
        if (burningCurrentLimitOf(bridgeAdapter) < amount) revert Controller_NotHighEnoughLimits();
        _useBurnerLimits(bridgeAdapter, amount);
        _burn(_msgSender(), amount);

        if (recipient == address(0)) revert Controller_Invalid_Params();
        if (getControllerForChain(destChainId) == address(0)) revert Controller_Chain_Not_Supported();
        if (transfersPausedTo[destChainId]) revert Controller_TransfersPausedToDestination();
        bytes32 transferId = calculateTransferId(destChainId);
        // Increment nonce used to create transfer id
        nonce++;

        // Store transfer data
        destChainForMessage[transferId] = destChainId;
        Transfer memory transfer = Transfer(recipient, amount, unwrap, 1, transferId);
        relayedTransfers[transferId] = transfer;

        IBaseAdapter(bridgeAdapter).relayMessage{value: msg.value}(
            destChainId,
            getControllerForChain(destChainId),
            bridgeOptions,
            abi.encode(transfer)
        );
        emit TransferCreated(transferId, destChainId, 1, _msgSender(), recipient, amount, unwrap);
        emit TransferRelayed(transferId, bridgeAdapter);
    }

    /**
     * @notice Resends a single-bridge transfer message to another chain via a bridgeAdapter
     * @notice Msg.sender will receive any refunds from excess fees paid by the bridge, if the bridge supports it.
     * @dev msg.value should contain the bridge adapter fee
     * @param transferId The unique identifier of the transfer.
     * @param adapter The address of the bridge adapter.
     * @param options Additional params to be used by the adapter.
     */
    function resendTransfer(bytes32 transferId, address adapter, bytes memory options) public payable nonReentrant whenNotPaused {
        uint256 destChainId = destChainForMessage[transferId];
        if (destChainId == 0) revert Controller_UnknownTransfer();
        Transfer memory transfer = relayedTransfers[transferId];
        if (transfer.threshold == 1) {
            uint256 _currentLimit = burningCurrentLimitOf(adapter);
            if (_currentLimit < transfer.amount) revert Controller_NotHighEnoughLimits();
            // Resend doesn't consume burn limits, since the asset is already burned, but it checks if the bridge adapter is enabled

            IBaseAdapter(adapter).relayMessage{value: msg.value}(destChainId, getControllerForChain(destChainId), options, abi.encode(transfer));
            emit TransferResent(transferId);
            emit TransferRelayed(transferId, adapter);
        } else {
            revert Controller_Invalid_Params();
        }
    }

    /**
     * @notice Sends a message to another chain via multiple bridgeAdapter to mint the asset, bypassing the individual bridge limits.
     * @notice This function uses instead higher limits, since execution goes through a minimum number of bridges.
     * @notice Msg.sender will receive any refunds from excess fees paid by the bridge, if the bridge supports it.
     * @dev Token allowance must be given before calling this function, which should include the multi-bridge fee, if any.
     * @param recipient The address of the recipient. Could be the same as msg.sender.
     * @param amount The amount of the asset to mint.
     * @param unwrap Applicable only to XERC20 transfers. Used to unwrap the native asset using the lockbox on destination, if enabled on the destination.
     * @param destChainId The destination chain ID.
     * @param adapters The addresses of the bridge adapters.
     * @param fees The fees to be paid to the bridge adapters.
     * @param options Additional params to be used by the adapter.
     */
    function transferTo(
        address recipient,
        uint256 amount,
        bool unwrap,
        uint256 destChainId,
        address[] memory adapters,
        uint256[] memory fees,
        bytes[] memory options
    ) public payable nonReentrant whenNotPaused {
        if (amount == 0) revert Controller_ZeroAmount();
        // Fee collection for multi-bridge transfers
        uint256 fee = feeCollector.quote(amount);
        if (fee > 0) {
            IERC20(token).safeTransferFrom(_msgSender(), address(this), fee);
            IERC20(token).safeApprove(address(feeCollector), fee);
            feeCollector.collect(token, fee);
        }
        _burn(_msgSender(), amount);

        uint256 _currentLimit = burningCurrentLimitOf(address(0));
        if (_currentLimit < amount) revert Controller_NotHighEnoughLimits();
        _useBurnerLimits(address(0), amount);

        _checkUniqueness(adapters);

        // Revert if threshold is higher than the number of adapters that will execute the message
        if (adapters.length < minBridges) revert Controller_Invalid_Params();
        if (recipient == address(0)) revert Controller_Invalid_Params();
        if (minBridges == 0) revert Controller_MultiBridgeTransfersDisabled();
        if (getControllerForChain(destChainId) == address(0)) revert Controller_Chain_Not_Supported();
        if (transfersPausedTo[destChainId]) revert Controller_TransfersPausedToDestination();
        // Create transfer id
        bytes32 transferId = calculateTransferId(destChainId);
        // Increment nonce used to create transfer id
        nonce++;
        Transfer memory transfer = Transfer(recipient, amount, unwrap, minBridges, transferId);

        // Store transfer data
        destChainForMessage[transferId] = destChainId;
        relayedTransfers[transferId] = transfer;

        _relayTransfer(transfer, destChainId, adapters, fees, options, msg.value);
        emit TransferCreated(transferId, destChainId, minBridges, _msgSender(), recipient, amount, unwrap);
    }

    /**
     * @notice Resends a multi-bridge transfer message to another chain via one or more multibridge whitelested bridge Adapters
     * @dev msg.value should contain the total bridge adapter fees
     * @param transferId The unique identifier of the transfer.
     * @param adapters The addresses of the bridge adapters.
     * @param fees The fees to be paid to the bridge adapters.
     * @param options Additional params to be used by the adapter.
     */
    function resendTransfer(
        bytes32 transferId,
        address[] memory adapters,
        uint256[] memory fees,
        bytes[] memory options
    ) public payable nonReentrant whenNotPaused {
        uint256 destChainId = destChainForMessage[transferId];
        if (destChainId == 0) revert Controller_UnknownTransfer();
        if (minBridges == 0) revert Controller_MultiBridgeTransfersDisabled();
        _checkUniqueness(adapters);
        Transfer memory transfer = relayedTransfers[transferId];
        // Resend doesn't uses the burn limits, since the asset is already burned and limits are global for all whitelisted multibridge adapters
        if (transfer.threshold > 1) {
            if (adapters.length != fees.length) revert Controller_Invalid_Params();

            _relayTransfer(transfer, destChainId, adapters, fees, options, msg.value);
            emit TransferResent(transferId);
        } else {
            revert Controller_Invalid_Params();
        }
    }

    /**
     * @notice Registers a received message.
     * @dev Can be called by an adapter contract only
     * @param receivedMsg The received message data in bytes.
     * @param originChain The origin chain ID.
     * @param originSender The address of the origin sender. (controller in origin chain)
     */
    function receiveMessage(bytes calldata receivedMsg, uint256 originChain, address originSender) public override nonReentrant {
        // OriginSender must be a controller on another chain
        if (getControllerForChain(originChain) != originSender) revert Controller_Invalid_Params();

        // Decode message
        Transfer memory transfer = abi.decode(receivedMsg, (Transfer));

        if (transfer.threshold == 1) {
            // Instant transfer using the bridge limits
            // Check that transfer hasn't been replayed
            if (receivedTransfers[transfer.transferId].amount != 0) revert Controller_TransferNotExecutable();
            receivedTransfers[transfer.transferId] = ReceivedTransfer({
                recipient: transfer.recipient,
                amount: transfer.amount,
                unwrap: transfer.unwrap,
                receivedSoFar: 1,
                threshold: 1,
                originChainId: originChain,
                executed: true
            });

            // Get limit of bridge
            uint256 _currentLimit = mintingCurrentLimitOf(msg.sender);
            if (_currentLimit < transfer.amount) revert Controller_NotHighEnoughLimits();
            _useMinterLimits(msg.sender, transfer.amount);

            if (transfer.unwrap && allowTokenUnwrapping) {
                _unwrapAndMint(transfer.recipient, transfer.amount);
            } else {
                _mint(transfer.recipient, transfer.amount);
            }
            emit TransferExecuted(transfer.transferId);
        } else {
            // Msg.sender needs to be a multibridge adapter
            if (!multiBridgeAdapters[msg.sender]) revert Controller_AdapterNotSupported();
            if (deliveredBy[transfer.transferId][msg.sender] == true) revert Controller_TransferResentByAadapter();
            deliveredBy[transfer.transferId][msg.sender] = true;

            ReceivedTransfer memory receivedTransfer = receivedTransfers[transfer.transferId];
            // Multi-bridge transfer
            if (receivedTransfer.receivedSoFar == 0) {
                receivedTransfer = ReceivedTransfer({
                    recipient: transfer.recipient,
                    amount: transfer.amount,
                    unwrap: transfer.unwrap,
                    receivedSoFar: 1,
                    threshold: transfer.threshold,
                    originChainId: originChain,
                    executed: false
                });
            } else {
                receivedTransfer.receivedSoFar++;
            }
            // Check if the transfer can be executed
            if (receivedTransfer.receivedSoFar >= receivedTransfer.threshold) {
                emit TransferExecutable(transfer.transferId);
            }
            receivedTransfers[transfer.transferId] = receivedTransfer;
        }
        emit TransferReceived(transfer.transferId, originChain, msg.sender);
    }

    /**
     * @notice Executes a received multibridge transfer. Anyone can execute a transfer
     * @param transferId The unique identifier of the transfer.
     */
    function execute(bytes32 transferId) public nonReentrant whenNotPaused {
        ReceivedTransfer storage transfer = receivedTransfers[transferId];
        if (transfer.amount == 0) revert Controller_UnknownTransfer();
        if (transfer.executed) revert Controller_TransferNotExecutable();
        if (transfer.receivedSoFar < transfer.threshold) revert Controller_ThresholdNotMet();
        uint256 _currentLimit = mintingCurrentLimitOf(address(0));
        if (_currentLimit < transfer.amount) revert Controller_NotHighEnoughLimits();
        _useMinterLimits(address(0), transfer.amount);
        transfer.executed = true;

        if (transfer.unwrap && allowTokenUnwrapping) {
            _unwrapAndMint(transfer.recipient, transfer.amount);
        } else {
            _mint(transfer.recipient, transfer.amount);
        }

        emit TransferExecuted(transferId);
    }

    /* ========== VIEW ========== */

    /**
     * @notice Returns the controller address for a given chain ID.
     * @param chainId The chain ID.
     * @return The controller address.
     */
    function getControllerForChain(uint256 chainId) public view override returns (address) {
        return _controllerForChain[chainId];
    }

    /**
     * @notice Calculates the transfer ID based on the provided parameters.
     * @param destChainId The destination chain ID.
     * @return The calculated transfer ID.
     */
    function calculateTransferId(uint256 destChainId) public view returns (bytes32) {
        return keccak256(abi.encode(destChainId, block.chainid, nonce));
    }

    /* ========== ADMIN ========== */

    function setTokenUnwrapping(bool _allowUnwrapping) public virtual onlyRole(DEFAULT_ADMIN_ROLE) {
        allowTokenUnwrapping = _allowUnwrapping;
        emit AllowTokenUnwrappingSet(_allowUnwrapping);
    }

    /**
     * @notice Sets the controller addresses for the given chain IDs.
     * @dev This also serves -in a way- as the token mappers for the token according to xERC20
     * @param chainId The list of chain IDs.
     * @param controller The list of controller addresses.
     */
    function setControllerForChain(uint256[] memory chainId, address[] memory controller) public onlyRole(DEFAULT_ADMIN_ROLE) {
        _setControllerForChain(chainId, controller);
    }

    /**
     * @notice Pauses or unpauses the initiation of new transfers to a specific chain.
     * @dev Only the owner can call this function.
     * @param _chainId The chain ID to pause or unpause transfers to.
     * @param _pause True to pause transfers, false to unpause.
     */
    function pauseTransfersToChain(uint256 _chainId, bool _pause) public onlyRole(DEFAULT_ADMIN_ROLE) {
        transfersPausedTo[_chainId] = _pause;
        emit TransfersPausedToChain(_chainId, _pause);
    }

    /**
     * @notice Sets the minimum number of bridges required to relay an asset for multi-bridge transfers.
     * @dev Setting to 0 will disable multi-bridge transfers.
     * @param _minBridges The minimum number of bridges required.
     */
    function setMinBridges(uint256 _minBridges) public onlyRole(DEFAULT_ADMIN_ROLE) {
        minBridges = _minBridges;
        emit MinBridgesSet(_minBridges);
    }

    /**
     * @notice Adds a bridge adapter to the whitelist for multibridge transfers.
     * @dev adapter and enabledmust have the same length.
     * @param adapter An array of adapter addresses of the bridge adapters.
     * @param enabled An array of the status of the adapters. True to enable, false to disable.
     */
    function setMultiBridgeAdapters(address[] memory adapter, bool[] memory enabled) public onlyRole(DEFAULT_ADMIN_ROLE) {
        if (adapter.length != enabled.length) revert Controller_Invalid_Params();
        for (uint256 i = 0; i < adapter.length; i++) {
            multiBridgeAdapters[adapter[i]] = enabled[i];
            emit MultiBridgeAdapterSet(adapter[i], enabled[i]);
        }
    }

    /**
     *@notice Withdraws the contract balance to the recipient address.
     * @dev Only the owner can call this function.
     * @param recipient The address to which the contract balance will be transferred.
     */
    function withdraw(address payable recipient) public onlyRole(DEFAULT_ADMIN_ROLE) {
        if (recipient == address(0)) revert Controller_Invalid_Params();

        (bool success, ) = recipient.call{value: address(this).balance}("");
        if (!success) revert Controller_EtherTransferFailed();
    }

    /* ========== INTERNAL ========== */

    /**
     * @notice Mints the asset to the recipient address, using the MINT_SELECTOR.
     * @param recipient The address of the recipient.
     * @param amount The amount of the asset to mint.
     */
    function _mint(address recipient, uint256 amount) internal virtual {
        (bool success, ) = token.call(abi.encodeWithSelector(MINT_SELECTOR, recipient, amount));
        if (!success) revert Controller_TokenMintFailed();
    }

    /**
     * @notice Burns the asset from the account address, using the burnSelector.
     * @param account The address of the account to burn from.
     * @param amount The amount of the asset to burn.
     */
    function _burn(address account, uint256 amount) internal virtual {
        uint256 balance = IERC20(token).balanceOf(account);
        bool success;
        if (BURN_SELECTOR == BURN_SELECTOR_SINGLE) {
            // burn(uint256) implementations expect msg.sender to hold the tokens
            IERC20(token).safeTransferFrom(account, address(this), amount);
            (success, ) = token.call(abi.encodeWithSelector(BURN_SELECTOR, amount));
        } else {
            (success, ) = token.call(abi.encodeWithSelector(BURN_SELECTOR, account, amount));
        }
        uint256 newBalance = IERC20(token).balanceOf(account);
        if (!success || (newBalance != balance - amount)) revert Controller_TokenBurnFailed();
    }

    /**
     * @notice Relays a message to another chain.
     * @notice Msg.sender will receive any refunds from excess fees paid by the bridge, if the bridge supports it.
     * @param transfer The Transfer struct with the transfer data.
     * @param destChainId The destination chain ID.
     * @param adapters The list of adapter addresses.
     * @param fees The list of fees for each adapter.
     * @param totalFees The msg.value passed to the function that should cover the sum of all the fees. Will revert if sum of fees is not equal to totalFees.
     */
    function _relayTransfer(
        Transfer memory transfer,
        uint256 destChainId,
        address[] memory adapters,
        uint256[] memory fees,
        bytes[] memory options,
        uint256 totalFees
    ) internal {
        if ((adapters.length != fees.length) || (adapters.length != options.length)) revert Controller_Invalid_Params();
        uint256 fee;
        for (uint256 i = 0; i < adapters.length; i++) {
            // Check that provided bridges are whitelisted
            if (multiBridgeAdapters[adapters[i]] == false) revert Controller_AdapterNotSupported();
            IBaseAdapter(adapters[i]).relayMessage{value: fees[i]}(destChainId, getControllerForChain(destChainId), options[i], abi.encode(transfer));
            emit TransferRelayed(transfer.transferId, adapters[i]);
            fee += fees[i];
        }
        if (fee != totalFees) revert Controller_FeesSumMismatch();
    }

    /**
     * @notice Sets the controller addresses for the given chain IDs.
     * @param chainId The list of chain IDs.
     * @param controller The list of controller addresses.
     */
    function _setControllerForChain(uint256[] memory chainId, address[] memory controller) internal {
        if (chainId.length != controller.length) revert Controller_Invalid_Params();
        for (uint256 i = 0; i < chainId.length; i++) {
            _controllerForChain[chainId[i]] = controller[i];
            emit ControllerForChainSet(controller[i], chainId[i]);
        }
    }

    /**
     * @notice If there is a XERC20Lockbox set in the token, unwrap the asset and send it to the recipient. If not, mint the tokens directly.
     * @dev Checks that all external calls will succeed, otherwise it returns the tokens to the user.
     * @param recipient The address of the recipient.
     * @param amount The amount of the asset to unwrap and mint.
     */
    function _unwrapAndMint(address recipient, uint256 amount) internal virtual {
        // Try to get the lockbox address from the token
        (bool success, bytes memory data) = token.call(abi.encodeWithSignature("lockbox()"));

        // Check if lockbox call was successful and returned data
        if (success && data.length != 0) {
            address lockbox = abi.decode(data, (address));

            // Only attempt unwrapping if lockbox exists
            if (lockbox != address(0)) {
                // Store initial balance to calculate exact amount after minting
                uint256 balanceBefore = IERC20(token).balanceOf(address(this));

                // Mint tokens to this contract
                _mint(address(this), amount);

                // Calculate exact amount received (accounts for potential taxes/fees)
                uint256 amountToUnwrap = IERC20(token).balanceOf(address(this)) - balanceBefore;

                // Get the underlying token address from lockbox
                (bool addrRetrSuccess, bytes memory underlying) = lockbox.call(abi.encodeWithSignature("ERC20()"));

                // Approve tokens for unwrapping
                (success, ) = token.call(abi.encodeWithSignature("approve(address,uint256)", lockbox, amountToUnwrap));

                // If approval failed or underlying token retrieval failed or allowance is insufficient
                if (!success || !addrRetrSuccess || IERC20(token).allowance(address(this), lockbox) < amountToUnwrap) {
                    // Transfer tokens directly to recipient without unwrapping
                    IERC20(token).safeTransfer(recipient, amountToUnwrap);
                    return;
                }

                // Decode underlying token address
                address underlyingToken = abi.decode(underlying, (address));

                // If underlying token is address(0), can't unwrap
                if (underlyingToken == address(0)) {
                    IERC20(token).safeTransfer(recipient, amountToUnwrap);
                    return;
                }

                // Try to withdraw/unwrap tokens
                (success, ) = lockbox.call(abi.encodeWithSignature("withdraw(uint256)", amountToUnwrap));

                // If withdrawal failed, send the wrapped tokens directly
                if (!success) {
                    IERC20(token).safeTransfer(recipient, amountToUnwrap);
                    return;
                }

                // Transfer unwrapped/underlying tokens to recipient
                IERC20(underlyingToken).safeTransfer(recipient, amountToUnwrap);
                return;
            }
        }

        // If lockbox doesn't exist or can't be used, mint tokens directly to recipient
        _mint(recipient, amount);
    }

    /// @dev Execution will revert if there is a duplicate adapter in the array
    function _checkUniqueness(address[] memory adapters) internal pure {
        uint256 length = adapters.length;
        for (uint256 i = 0; i < length - 1; i++) {
            for (uint256 j = i + 1; j < length; j++) {
                // Verify that the adapter is not a duplicate
                if (adapters[i] == adapters[j]) revert Controller_DuplicateAdapter();
            }
        }
    }

    ///@dev Fallback function to receive ether from bridge refunds
    receive() external payable {}
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.19;

import {Pausable} from "@openzeppelin/contracts/security/Pausable.sol";
import {AccessControl} from "@openzeppelin/contracts/access/AccessControl.sol";

/**
 * @title BaseAssetBridge
 */
abstract contract BaseAssetBridge is AccessControl, Pausable {
    /**
     * @notice Error thrown when invalid parameters are provided.
     */
    error Controller_Invalid_Params();

    /**
     * @notice Error thrown when new limits are too high.
     */
    error Controller_LimitsTooHigh();

    /**
     * @notice Emits when a limit is set
     *
     * @param _mintingLimit The updated minting limit we are setting to the bridge
     * @param _burningLimit The updated burning limit we are setting to the bridge
     * @param _bridge The address of the bridge we are setting the limit too
     */
    event BridgeLimitsSet(uint256 _mintingLimit, uint256 _burningLimit, address indexed _bridge);

    /**
     * @notice Reverts when a user with too low of a limit tries to call mint/burn
     */
    error Controller_NotHighEnoughLimits();

    /**
     * @notice Contains the full minting and burning data for a particular bridge
     *
     * @param minterParams The minting parameters for the bridge
     * @param burnerParams The burning parameters for the bridge
     */
    struct Bridge {
        BridgeParameters minterParams;
        BridgeParameters burnerParams;
    }

    /**
     * @notice Contains the mint or burn parameters for a bridge
     *
     * @param timestamp The timestamp of the last mint/burn
     * @param ratePerSecond The rate per second of the bridge
     * @param maxLimit The max limit of the bridge
     * @param currentLimit The current limit of the bridge
     */
    struct BridgeParameters {
        uint256 timestamp;
        uint256 ratePerSecond;
        uint256 maxLimit;
        uint256 currentLimit;
    }

    /**
     * @notice The role that allows an address to pause the contract
     */
    bytes32 public constant PAUSE_ROLE = keccak256("PAUSE_ROLE");

    /**
     * @notice The duration it takes for the limits to fully replenish
     */
    uint256 public duration;

    /**
     * @notice Maps bridge address to bridge configurations
     */
    mapping(address => Bridge) public bridges;

    /**
     * @notice The constructor for the BaseAssetBridge
     *
     * @param _owner The user getting the DEFAULT_ADMIN_ROLE and PAUSE_ROLE.
     * @param _pauser The user getting the PAUSE_ROLE.
     * @param _duration The duration it takes for the limits to fully replenish.
     * @param _bridges The list of bridge adapter addresses that have limits set for minting and burning.
     * @param _mintingLimits The list of minting limits for the bridge adapters.
     * @param _burningLimits The list of burning limits for the bridge adapters.
     */
    constructor(
        address _owner,
        address _pauser,
        uint256 _duration,
        address[] memory _bridges,
        uint256[] memory _mintingLimits,
        uint256[] memory _burningLimits
    ) {
        _setupRole(DEFAULT_ADMIN_ROLE, _owner);
        _setupRole(PAUSE_ROLE, _owner);
        _grantRole(PAUSE_ROLE, _pauser);
        if (_duration == 0) revert Controller_Invalid_Params();
        duration = _duration;
        if ((_bridges.length != _mintingLimits.length) || (_bridges.length != _burningLimits.length)) revert Controller_Invalid_Params();
        if (_bridges.length > 0) {
            for (uint256 i = 0; i < _bridges.length; i++) {
                _setLimits(_bridges[i], _mintingLimits[i], _burningLimits[i]);
            }
        }
    }

    /**
     * @notice Updates the limits of any bridge
     * @dev Can only be called by the owner
     * @param _mintingLimit The updated minting limit we are setting to the bridge
     * @param _burningLimit The updated burning limit we are setting to the bridge
     * @param _bridge The address of the bridge we are setting the limits too
     */
    function setLimits(address _bridge, uint256 _mintingLimit, uint256 _burningLimit) external onlyRole(DEFAULT_ADMIN_ROLE) {
        _setLimits(_bridge, _mintingLimit, _burningLimit);
    }

    /**
     * @notice Returns the max limit of a bridge
     *
     * @param _bridge the bridge we are viewing the limits of
     * @return _limit The limit the bridge has
     */

    function mintingMaxLimitOf(address _bridge) public view returns (uint256 _limit) {
        _limit = bridges[_bridge].minterParams.maxLimit;
    }

    /**
     * @notice Returns the max limit of a bridge
     *
     * @param _bridge the bridge we are viewing the limits of
     * @return _limit The limit the bridge has
     */

    function burningMaxLimitOf(address _bridge) public view returns (uint256 _limit) {
        _limit = bridges[_bridge].burnerParams.maxLimit;
    }

    /**
     * @notice Returns the current limit of a bridge
     *
     * @param _bridge the bridge we are viewing the limits of
     * @return _limit The limit the bridge has
     */

    function mintingCurrentLimitOf(address _bridge) public view returns (uint256 _limit) {
        _limit = _getCurrentLimit(
            bridges[_bridge].minterParams.currentLimit,
            bridges[_bridge].minterParams.maxLimit,
            bridges[_bridge].minterParams.timestamp,
            bridges[_bridge].minterParams.ratePerSecond
        );
    }

    /**
     * @notice Returns the current limit of a bridge
     *
     * @param _bridge the bridge we are viewing the limits of
     * @return _limit The limit the bridge has
     */

    function burningCurrentLimitOf(address _bridge) public view returns (uint256 _limit) {
        _limit = _getCurrentLimit(
            bridges[_bridge].burnerParams.currentLimit,
            bridges[_bridge].burnerParams.maxLimit,
            bridges[_bridge].burnerParams.timestamp,
            bridges[_bridge].burnerParams.ratePerSecond
        );
    }

    /**
     * @notice Pauses the contract
     * @dev Only the owner can call this function.
     */
    function pause() external onlyRole(PAUSE_ROLE) {
        _pause();
    }

    /**
     * @notice Unpauses the contract
     * @dev Only the owner can call this function.
     */
    function unpause() external onlyRole(PAUSE_ROLE) {
        _unpause();
    }

    /**
     * @notice Updates the limits of any bridge
     * @param _mintingLimit The updated minting limit we are setting to the bridge
     * @param _burningLimit The updated burning limit we are setting to the bridge
     * @param _bridge The address of the bridge we are setting the limits too
     */
    function _setLimits(address _bridge, uint256 _mintingLimit, uint256 _burningLimit) internal {
        // Ensure new limits do not cause overflows
        if (_mintingLimit > (type(uint256).max / 2) || _burningLimit > (type(uint256).max / 2)) {
            revert Controller_LimitsTooHigh();
        }

        _changeMinterLimit(_bridge, _mintingLimit);
        _changeBurnerLimit(_bridge, _burningLimit);
        emit BridgeLimitsSet(_mintingLimit, _burningLimit, _bridge);
    }

    /**
     * @notice Uses the limit of any bridge
     * @param _bridge The address of the bridge who is being changed
     * @param _change The change in the limit
     */

    function _useMinterLimits(address _bridge, uint256 _change) internal {
        uint256 _currentLimit = mintingCurrentLimitOf(_bridge);
        bridges[_bridge].minterParams.timestamp = block.timestamp;
        bridges[_bridge].minterParams.currentLimit = _currentLimit - _change;
    }

    /**
     * @notice Uses the limit of any bridge
     * @param _bridge The address of the bridge who is being changed
     * @param _change The change in the limit
     */

    function _useBurnerLimits(address _bridge, uint256 _change) internal {
        uint256 _currentLimit = burningCurrentLimitOf(_bridge);
        bridges[_bridge].burnerParams.timestamp = block.timestamp;
        bridges[_bridge].burnerParams.currentLimit = _currentLimit - _change;
    }

    /**
     * @notice Updates the limit of any bridge
     * @dev Can only be called by the owner
     * @param _bridge The address of the bridge we are setting the limit too
     * @param _limit The updated limit we are setting to the bridge
     */

    function _changeMinterLimit(address _bridge, uint256 _limit) internal {
        uint256 _oldLimit = bridges[_bridge].minterParams.maxLimit;
        uint256 _currentLimit = mintingCurrentLimitOf(_bridge);
        bridges[_bridge].minterParams.maxLimit = _limit;

        bridges[_bridge].minterParams.currentLimit = _calculateNewCurrentLimit(_limit, _oldLimit, _currentLimit);

        bridges[_bridge].minterParams.ratePerSecond = _limit / duration;
        bridges[_bridge].minterParams.timestamp = block.timestamp;
    }

    function _changeBurnerLimit(address _bridge, uint256 _limit) internal {
        uint256 _oldLimit = bridges[_bridge].burnerParams.maxLimit;
        uint256 _currentLimit = burningCurrentLimitOf(_bridge);
        bridges[_bridge].burnerParams.maxLimit = _limit;

        bridges[_bridge].burnerParams.currentLimit = _calculateNewCurrentLimit(_limit, _oldLimit, _currentLimit);

        bridges[_bridge].burnerParams.ratePerSecond = _limit / duration;
        bridges[_bridge].burnerParams.timestamp = block.timestamp;
    }

    /**
     * @notice Updates the current limit
     *
     * @param _limit The new limit
     * @param _oldLimit The old limit
     * @param _currentLimit The current limit
     * @return _newCurrentLimit The new current limit
     */

    function _calculateNewCurrentLimit(uint256 _limit, uint256 _oldLimit, uint256 _currentLimit) internal pure returns (uint256 _newCurrentLimit) {
        uint256 _difference;

        if (_oldLimit > _limit) {
            _difference = _oldLimit - _limit;
            _newCurrentLimit = _currentLimit > _difference ? _currentLimit - _difference : 0;
        } else {
            _difference = _limit - _oldLimit;
            _newCurrentLimit = _currentLimit + _difference;
        }
    }

    /**
     * @notice Gets the current limit
     *
     * @param _currentLimit The current limit
     * @param _maxLimit The max limit
     * @param _timestamp The timestamp of the last update
     * @param _ratePerSecond The rate per second
     * @return _limit The current limit
     */

    function _getCurrentLimit(
        uint256 _currentLimit,
        uint256 _maxLimit,
        uint256 _timestamp,
        uint256 _ratePerSecond
    ) internal view returns (uint256 _limit) {
        _limit = _currentLimit;
        if (_limit == _maxLimit) {
            return _limit;
        } else if (_timestamp + duration <= block.timestamp) {
            _limit = _maxLimit;
        } else if (_timestamp + duration > block.timestamp) {
            uint256 _timePassed = block.timestamp - _timestamp;
            uint256 _calculatedLimit = _limit + (_timePassed * _ratePerSecond);
            _limit = _calculatedLimit > _maxLimit ? _maxLimit : _calculatedLimit;
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity >=0.8.19 <=0.8.20;

interface IController {
    /**
     * @notice Registers a received message.
     * @param message The received message data in bytes.
     * @param originChain The origin chain ID.
     * @param originSender The address of the origin sender. (controller in origin chain)
     */
    function receiveMessage(bytes calldata message, uint256 originChain, address originSender) external;

    /**
     * @notice Returns the controller address for a given chain ID.
     * @param chainId The chain ID.
     * @return The controller address.
     */
    function getControllerForChain(uint256 chainId) external view returns (address);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.19;

interface IFeeCollector {
    function collect(address token, uint256 amount) external;

    function quote(uint256 amount) external view returns (uint256 fee);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.19;

import {AssetController, SafeERC20, IERC20} from "./AssetController.sol";

/**
 * @title LockReleaseAssetController
 * @notice An implementation of the AssetController but instead of burning/minting tokens, it locks and releases ERC20s.
 */
contract LockReleaseAssetController is AssetController {
    using SafeERC20 for IERC20;

    /// @notice Event emitted when liquidity is added
    /// @param amount The amount of tokens added to the pool
    event LiquidityAdded(uint256 amount);

    /// @notice Event emitted when liquidity is removed
    /// @param amount The amount of tokens removed from the pool
    event LiquidityRemoved(uint256 amount);

    /// @notice Error thrown when XERC20 token unwrapping is not supported
    error Controller_UnwrappingNotSupported();

    /// @notice Error thrown when there are not enough tokens in the pool
    error Controller_NotEnoughTokensInPool();

    /**
     * @notice Initializes the contract with the given parameters.
     * @dev To configure multibridge limits, use the zero address as a bridge in `_bridges` and set the limits accordingly.
     * @param _addresses An array with four elements, containing the token address, the user that gets DEFAULT_ADMIN_ROLE and PAUSE_ROLE, the user getting only PAUSE_ROLE,
     *          the fee collector contract, the controller address in other chains for the given chain IDs (if deployed with create3).
     * @param _duration The duration it takes for the limits to fully replenish.
     * @param _minBridges The minimum number of bridges required to relay an asset for multi-bridge transfers. Setting to 0 will disable multi-bridge transfers.
     * @param _multiBridgeAdapters The addresses of the initial bridge adapters that can be used for multi-bridge transfers, bypassing the limits.
     * @param _chainId The list of chain IDs to set the controller addresses for.
     * @param _bridges The list of bridge adapter addresses that have limits set for minting and burning.
     * @param _mintingLimits The list of minting limits for the bridge adapters. It must correspond to the mint() function of the token, otherwise tokens cannot be minted
     * @param _burningLimits The list of burning limits for the bridge adapters. It must correspond to the burn() function of the token, otherwise tokens cannot be burned
     * @param _selectors Mint and burn function selectors. An empty bytes4 should be passed.
     */
    constructor(
        address[5] memory _addresses, //token, initialOwner, pauser, feeCollector, controllerAddress
        uint256 _duration,
        uint256 _minBridges,
        address[] memory _multiBridgeAdapters,
        uint256[] memory _chainId,
        address[] memory _bridges,
        uint256[] memory _mintingLimits,
        uint256[] memory _burningLimits,
        bytes4[2] memory _selectors
    ) AssetController(_addresses, _duration, _minBridges, _multiBridgeAdapters, _chainId, _bridges, _mintingLimits, _burningLimits, _selectors) {}

    /**
     * @notice Overrides the setTokenUnwrapping function to revert, as unwrapping is not supported in this implementation.
     */
    function setTokenUnwrapping(bool) public view override onlyRole(DEFAULT_ADMIN_ROLE) {
        revert Controller_UnwrappingNotSupported();
    }

    /**
     * @notice Releases the given amount of tokens from the pool.
     * @dev Overwides the default mint implementation to release tokens from the pool.
     * @param _to The address to which the tokens will be sent.
     * @param _amount The amount of tokens to be sent.
     */
    function _mint(address _to, uint256 _amount) internal override {
        if (IERC20(token).balanceOf(address(this)) < _amount) revert Controller_NotEnoughTokensInPool();
        IERC20(token).safeTransfer(_to, _amount);
        emit LiquidityRemoved(_amount);
    }

    /**
     * @notice Locks the given amount of tokens in the pool.
     * @dev Overrides the default burn implementation to lock tokens in the pool.
     * @param _from The address from which the tokens will be taken.
     * @param _amount The amount of tokens to be locked.
     */
    function _burn(address _from, uint256 _amount) internal override {
        IERC20(token).safeTransferFrom(_from, address(this), _amount);
        emit LiquidityAdded(_amount);
    }

    /**
     * @notice Unwraps and mints the given amount of tokens.
     * @dev Overrides the default unwrapAndMint implementation to mint tokens directly, as there is no unwrap functionality.
     * @param _to The address to which the tokens will be sent.
     * @param _amount The amount of tokens to be sent.
     */
    function _unwrapAndMint(address _to, uint256 _amount) internal override {
        _mint(_to, _amount);
    }
}