Contract Source Code:

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

pragma solidity ^0.8.19;

import {BasicAccessControl} from "../shared/BasicAccessControl.sol";

contract MiningFee is BasicAccessControl {
    event Fee(address owner, uint256 amount, uint256 createAt);

    struct UserFee {
        FEE_STATUS status;
        uint256 createdAt;
        uint256 updatedAt;
    }

    enum FEE_STATUS {
        NONE,
        NO_FEE,
        FEE
    }

    mapping(address => UserFee) public userFeeStatus;

    uint256 public fee = 1 ether;
    uint256 public resetTime = 24 hours;

    function mineWithFee() external payable {
        require(msg.value == fee, "Fee provided is insufficient");
        UserFee storage userFee = userFeeStatus[msg.sender];

        uint256 currentTime = block.timestamp;
        uint256 resetTimeExpirey = userFee.updatedAt + resetTime;

        require(
            currentTime > resetTimeExpirey ||
                userFee.status == FEE_STATUS.NO_FEE ||
                userFee.status == FEE_STATUS.NONE,
            "User already paid the fee"
        );
        uint256 createdAt = userFee.createdAt;
        if (createdAt == 0) userFee.createdAt = currentTime;
        userFee.updatedAt = currentTime;
        userFee.status = FEE_STATUS.FEE;

        emit Fee(msg.sender, msg.value, block.timestamp);
    }

    function mineWithNoFee() external payable {
        require(msg.value == 0, "No fee required");

        UserFee storage userFee = userFeeStatus[msg.sender];

        uint256 currentTime = block.timestamp;
        uint256 resetTimeExpirey = userFee.updatedAt + resetTime;

        require(
            currentTime > resetTimeExpirey ||
                userFeeStatus[msg.sender].status == FEE_STATUS.NONE,
            "User already paid the fee"
        );
        uint256 createdAt = userFee.createdAt;
        if (createdAt == 0) userFee.createdAt = currentTime;
        userFee.updatedAt = currentTime;
        userFee.status = FEE_STATUS.NO_FEE;

        emit Fee(msg.sender, 0, block.timestamp);
    }

    function updateFee(uint256 _fee) external onlyModerators {
        fee = _fee;
    }

    function updateResetTime(uint256 _resetTime) external onlyModerators {
        resetTime = _resetTime;
    }

    function withdraw() external onlyOwner {
        (bool success, ) = msg.sender.call{value: address(this).balance}("");
        require(success, "transfer failed");
    }
}

// SPDX-License-Identifier: UNLICENSED

pragma solidity >=0.8.2;

import "@openzeppelin/contracts/access/Ownable.sol";

contract BasicAccessControl is Ownable {
    uint16 public totalModerators = 0;
    mapping(address => bool) public moderators;
    bool public isMaintaining = false;

    modifier onlyModerators() {
        require(
            _msgSender() == owner() || moderators[_msgSender()] == true,
            "Restricted Access!"
        );
        _;
    }

    modifier isActive() {
        require(!isMaintaining);
        _;
    }

    function addModerator(address _newModerator) public onlyOwner {
        if (moderators[_newModerator] == false) {
            moderators[_newModerator] = true;
            totalModerators += 1;
        } else {
            delete moderators[_newModerator];
            totalModerators -= 1;
        }
    }

    function updateMaintaining(bool _isMaintaining) public onlyOwner {
        isMaintaining = _isMaintaining;
    }
}