Contract Source Code:

pragma solidity >=0.4.21 <0.7.0;

contract TessaManager {
    string public name = "TESSA MANAGER @2020";

    address internal _owner;
    mapping (address => bool) internal _whitelist;
    mapping (address => bool) internal _managers;

    event SetWhitelist(address indexed _addr, bool state);
    event SetManager(address indexed _addr, bool state);

    constructor() public {
        _owner = msg.sender;
        setWhitelist(msg.sender, true);
        setManager(msg.sender, true);
    }

    function setWhitelist(address _addr, bool state) public returns (bool) {
        require(msg.sender == _owner, "owner:false");
        require(_addr != address(0), "addr:0x0");
        _whitelist[_addr] = state;
        emit SetWhitelist(_addr, state);
        return true;
    }

    function isWhitelist(address _addr) public view returns (bool) {
        require(_addr != address(0), "addr:0x0");
        return _whitelist[_addr];
    }

    function setManager(address _addr, bool state) public returns (bool) {
        require(msg.sender == _owner, "owner:false");
        require(_addr != address(0), "addr:0x0");
        _managers[_addr] = state;
        _whitelist[_addr] = state;
        emit SetManager(_addr, state);
        emit SetWhitelist(_addr, state);
        return true;
    }

    function isManager(address _addr) public view returns (bool) {
        require(_addr != address(0), "addr:0x0");
        return _managers[_addr];
    }
}

pragma solidity >=0.4.21 <0.7.0;

import "./TessaManager.sol";

/**
 * @title SafeMath
 * @dev Math operations with safety checks that throw on error
 */
library SafeMath {
    /**
    * @dev Multiplies two numbers, throws on overflow.
    */
    function mul(uint256 _a, uint256 _b) internal pure returns (uint256 c) {
        // Gas optimization: this is cheaper than asserting 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-solidity/pull/522
        if (_a == 0) {
            return 0;
        }

        c = _a * _b;
        assert(c / _a == _b);
        return c;
    }

    /**
    * @dev Integer division of two numbers, truncating the quotient.
    */
    function div(uint256 _a, uint256 _b) internal pure returns (uint256) {
        // assert(_b > 0); // Solidity automatically throws when dividing by 0
        // uint256 c = _a / _b;
        // assert(_a == _b * c + _a % _b); // There is no case in which this doesn't hold
        return _a / _b;
    }

    /**
    * @dev Subtracts two numbers, throws on overflow (i.e. if subtrahend is greater than minuend).
    */
    function sub(uint256 _a, uint256 _b) internal pure returns (uint256) {
        assert(_b <= _a);
        return _a - _b;
    }

    /**
    * @dev Adds two numbers, throws on overflow.
    */
    function add(uint256 _a, uint256 _b) internal pure returns (uint256 c) {
        c = _a + _b;
        assert(c >= _a);
        return c;
    }
}

/**
 * @title IERC20 interface
 * @dev see https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/token/ERC20/IERC20.sol
 */
interface IERC20 {
    function totalSupply() external view returns (uint256);
    function balanceOf(address who) external view returns (uint256);
    function allowance(address owner, address spender) external view returns (uint256);

    function transfer(address to, uint256 value) external returns (bool);
    function approve(address spender, uint256 value) external returns (bool);
    function transferFrom(address from, address to, uint256 value) external returns (bool);

    event Transfer(address indexed from, address indexed to, uint256 value);
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

/**
 * @title Standard ERC20 token
 *
 * @dev Implementation of the basic standard token.
 * https://github.com/ethereum/EIPs/issues/20
 * Based on code by FirstBlood: https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol
 */
contract TessaToken is IERC20 {
    using SafeMath for uint256;

    mapping(address => uint256) internal balances;
    mapping(address => mapping(address => uint256)) internal allowed;

    uint256 internal totalSupply_;
    address internal issuer_;
    bool internal state_;

    TessaManager internal tManager_;

    event TransferFrom(address indexed issuer, address indexed from, address indexed to, uint256 value);

    function setManager(address _tmAddr) public returns (bool) {
        require(issuer_ == msg.sender, "issuer:false");
        tManager_ = TessaManager(_tmAddr);
        return true;
    }

    function setState(bool state) public returns (bool) {
        require(issuer_ == msg.sender, "issuer:false");
        state_ = state;
        return true;
    }

    function getState() public view returns (bool) {
        return state_;
    }

    /**
  * @dev Total number of tokens in existence
  */
    function totalSupply() public view returns (uint256) {
        return totalSupply_;
    }

    /**
  * @dev Gets the balance of the specified address.
  * @param _owner The address to query the the balance of.
  * @return An uint256 representing the amount owned by the passed address.
  */
    function balanceOf(address _owner) public view returns (uint256) {
        return balances[_owner];
    }

    /**
  * @dev Transfer token for a specified address
  * @param _to The address to transfer to.
  * @param _value The amount to be transferred.
  */
    function transfer(address _to, uint256 _value) public returns (bool) {
        require(state_, "state:false");
        require(_to != address(0), "addr:0x0");
        require(tManager_.isWhitelist(_to), "whitelist:false");
        require(_value <= balances[msg.sender], "balance:not enough");
        balances[msg.sender] = balances[msg.sender].sub(_value);
        balances[_to] = balances[_to].add(_value);
        emit Transfer(msg.sender, _to, _value);
        return true;
    }

    /**
   * @dev Transfer tokens from one address to another by manager
   * @param _from address The address which you want to send tokens from
   * @param _to address The address which you want to transfer to
   * @param _value uint256 the amount of tokens to be transferred
   */
    function transferFrom(address _from, address _to, uint256 _value) public returns (bool)
    {
        require(tManager_.isManager(msg.sender), "manager:false");
        require(state_, "state:false");
        require(_to != address(0), "addr:0x0");
        require(tManager_.isWhitelist(_to), "whitelist:false");
        require(_value <= balances[_from], "balance:not enough");
        balances[_from] = balances[_from].sub(_value);
        balances[_to] = balances[_to].add(_value);
        emit TransferFrom(msg.sender, _from, _to, _value);
        emit Transfer(_from, _to, _value);
        return true;
    }

    /**
   * @dev Approve the passed address to spend the specified amount of tokens on behalf of msg.sender.
   * Beware that changing an allowance with this method brings the risk that someone may use both the old
   * and the new allowance by unfortunate transaction ordering. One possible solution to mitigate this
   * race condition is to first reduce the spender's allowance to 0 and set the desired value afterwards:
   * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
   * @param _spender The address which will spend the funds.
   * @param _value The amount of tokens to be spent.
   */
    function approve(address _spender, uint256 _value) public returns (bool) {
        require(false, "Access denied!");
        // allowed[msg.sender][_spender] = _value;
        // emit Approval(msg.sender, _spender, _value);
        return false;
    }

    /**
   * @dev Function to check the amount of tokens that an owner allowed to a spender.
   * @param _owner address The address which owns the funds.
   * @param _spender address The address which will spend the funds.
   * @return A uint256 specifying the amount of tokens still available for the spender.
   */
    function allowance(address _owner, address _spender) public view returns (uint256)
    {
        require(false, "Access denied!");
        //return allowed[_owner][_spender];
        return 0;
    }

    /**
   * @dev Increase the amount of tokens that an owner allowed to a spender.
   * approve should be called when allowed[_spender] == 0. To increment
   * allowed value is better to use this function to avoid 2 calls (and wait until
   * the first transaction is mined)
   * From MonolithDAO Token.sol
   * @param _spender The address which will spend the funds.
   * @param _addedValue The amount of tokens to increase the allowance by.
   */
    function increaseApproval(address _spender, uint256 _addedValue) public returns (bool)
    {
        require(false, "Access denied!");
        // allowed[msg.sender][_spender] = (
        // allowed[msg.sender][_spender].add(_addedValue));
        // emit Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
        return true;
    }

    /**
   * @dev Decrease the amount of tokens that an owner allowed to a spender.
   * approve should be called when allowed[_spender] == 0. To decrement
   * allowed value is better to use this function to avoid 2 calls (and wait until
   * the first transaction is mined)
   * From MonolithDAO Token.sol
   * @param _spender The address which will spend the funds.
   * @param _subtractedValue The amount of tokens to decrease the allowance by.
   */
    function decreaseApproval(address _spender, uint256 _subtractedValue) public returns (bool)
    {
        require(false, "Access denied!");
        // uint256 oldValue = allowed[msg.sender][_spender];
        // if (_subtractedValue >= oldValue) {
        //   allowed[msg.sender][_spender] = 0;
        // } else {
        //   allowed[msg.sender][_spender] = oldValue.sub(_subtractedValue);
        // }
        // emit Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
        return true;
    }
}

pragma solidity >=0.4.21 <0.7.0;

import "./TessaToken.sol";

contract Tessa_0001_DH1 is TessaToken {
    string public name = "TESSA[#0001] : David Hockney [1]";
    string public symbol = "TSA";
    uint8 public decimals = 0;

    constructor(uint256 supply_, bool state, address addr_) public {
        totalSupply_ = supply_;
        balances[msg.sender] = totalSupply_;
        issuer_ = msg.sender;
        state_ = state;
        tManager_ = TessaManager(addr_);
    }
}