Contract Source Code:

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";

pragma solidity 0.8.19;

interface IQWN is IERC20Metadata {
    function mint(address to_, uint256 amount_) external;

    function burnFrom(address account_, uint256 amount_) external;

    function burn(uint256 amount_) external;

    function uniswapV2Pair() external view returns (address);

    function treasury() external view returns (address);
}

// SPDX-License-Identifier: AGPL-3.0
pragma solidity 0.8.19;

interface IStaking {
    function stake(address _to, uint256 _amount) external;

    function unstake(address _to, uint256 _amount, bool _rebase) external;

    function rebase() external;

    function index() external view returns (uint256);
}

pragma solidity 0.8.19;

interface IUniswapV2Router02 {
    function factory() external pure returns (address);

    function WETH() external pure returns (address);

    function addLiquidity(
        address tokenA,
        address tokenB,
        uint256 amountADesired,
        uint256 amountBDesired,
        uint256 amountAMin,
        uint256 amountBMin,
        address to,
        uint256 deadline
    ) external returns (uint256 amountA, uint256 amountB, uint256 liquidity);

    function addLiquidityETH(
        address token,
        uint256 amountTokenDesired,
        uint256 amountTokenMin,
        uint256 amountETHMin,
        address to,
        uint256 deadline
    )
        external
        payable
        returns (uint256 amountToken, uint256 amountETH, uint256 liquidity);

    function swapExactTokensForTokensSupportingFeeOnTransferTokens(
        uint256 amountIn,
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external;

    function swapExactETHForTokensSupportingFeeOnTransferTokens(
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external payable;

    function swapExactTokensForETHSupportingFeeOnTransferTokens(
        uint256 amountIn,
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external;

    function removeLiquidityETHSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountETH);
}

pragma solidity >=0.5.0;

interface IWETH {
    function deposit() external payable;

    function transfer(address to, uint value) external returns (bool);

    function transferFrom(
        address from,
        address to,
        uint value
    ) external returns (bool);

    function withdraw(uint) external;
}

// SPDX-License-Identifier: AGPL-3.0
pragma solidity 0.8.19;

import "@openzeppelin/contracts/access/Ownable.sol";
import "./interface/IUniswapV2Router02.sol";
import "./interface/IQWN.sol";
import "./interface/IWETH.sol";
import "./interface/IStaking.sol";

/// @title   QWAFeeHandler
/// @notice  Handles distributing fees for Quantum Wealth Accelerator
contract QWAFeeHandler is Ownable {
    /// EVENTS ///

    event ETHSwapped(uint256 amount, FEETYPE indexed feetype);

    /// VARIABLES ///

    enum FEETYPE {
        LIQUIDITY,
        BUYANDBURN,
        BUYANDSEND,
        ETHTOTREASURY
    }

    /// @notice Current fee type
    FEETYPE public feeType;
    /// @notice Swap ETH at amount
    uint256 public swapETHAtAmount;

    /// @notice Address of QWN
    address public immutable QWN;
    /// @notice Address of staking
    address public immutable staking;
    /// @notice Address of WETH
    address public immutable WETH;
    /// @notice Address of treasury
    address public immutable treasury;
    /// @notice Address for team fees
    address public constant teamAddress =
        0xdDd80699387a25C5BA00a2f1389de73d351C7d3C;

    /// @notice Address of UniswapV2Router
    IUniswapV2Router02 public immutable uniswapV2Router;

    /// CONSTRUCTOR ///

    constructor(address _QWN, address _staking, address _WETH) {
        IUniswapV2Router02 _uniswapV2Router = IUniswapV2Router02(
            0x7a250d5630B4cF539739dF2C5dAcb4c659F2488D
        );

        uniswapV2Router = _uniswapV2Router;

        swapETHAtAmount = 2.5 ether;

        QWN = _QWN;
        staking = _staking;
        WETH = _WETH;
        treasury = IQWN(QWN).treasury();

        feeType = FEETYPE.BUYANDSEND;
    }

    /// OWNER FUNCTIONS ///

    /// @notice Set fee type
    function setFeeType(FEETYPE _feeType) external onlyOwner {
        feeType = _feeType;
    }

    /// @notice ETH balance of contract to sawp
    function setSwapETHAtAmount(uint256 _swapETHAtAmount) external onlyOwner {
        swapETHAtAmount = _swapETHAtAmount;
    }

    /// CONVERT FEES ///

    /// @notice Convert fees to `FEETYPE`
    function convertFees() external {
        uint256 wethBalance = IERC20(WETH).balanceOf(address(this));
        if (wethBalance > 0) IWETH(WETH).withdraw(wethBalance);

        uint256 contractBalance = address(this).balance;
        bool canSwap = contractBalance >= swapETHAtAmount;

        if (canSwap) {
            uint256 teamFee = contractBalance / 3;
            bool success;
            (success, ) = address(teamAddress).call{value: teamFee}("");

            contractBalance = address(this).balance;
            if (feeType == FEETYPE.LIQUIDITY) {
                _addLiquidity(contractBalance);
            } else if (feeType == FEETYPE.BUYANDBURN) {
                _swapETHForQWN(contractBalance);
                IQWN(QWN).burn(IERC20(QWN).balanceOf(address(this)));
            } else if (feeType == FEETYPE.BUYANDSEND) {
                _swapETHForQWN(contractBalance);
                uint256 balance = IERC20(QWN).balanceOf(address(this));
                IERC20(QWN).approve(staking, balance);
                IStaking(staking).stake(treasury, balance);
            } else if (feeType == FEETYPE.ETHTOTREASURY) {
                IWETH(WETH).deposit{value: contractBalance}();
                IERC20(WETH).transfer(treasury, contractBalance);
            }
            emit ETHSwapped(contractBalance, feeType);
        }
    }

    //// INTERNAL FUNCTIONS ///

    /// @dev INTERNAL function to add swap ETH fees for QWN
    /// @dev Invoked in `_addLiquidity()` and `convertFees()`
    function _swapETHForQWN(uint256 _ethAmount) internal {
        address[] memory path = new address[](2);
        path[0] = WETH;
        path[1] = QWN;

        uniswapV2Router.swapExactETHForTokensSupportingFeeOnTransferTokens{
            value: _ethAmount
        }(0, path, address(this), block.timestamp);
    }

    /// @dev INTERNAL function to add ETH and QWN to liquidity
    /// @dev Invoked in `convertFees()`
    function _addLiquidity(uint256 _ethBalance) internal {
        _swapETHForQWN(_ethBalance / 2);
        uint256 qwnBalance = IERC20(QWN).balanceOf(address(this));
        IERC20(QWN).approve(address(uniswapV2Router), qwnBalance);

        uniswapV2Router.addLiquidityETH{value: address(this).balance}(
            QWN,
            qwnBalance,
            0,
            0,
            treasury,
            block.timestamp
        );
    }

    /// RECEIVE ///

    receive() external payable {}
}