Contract Source Code:

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import "@openzeppelin/contracts/utils/Address.sol";
import "@openzeppelin/contracts/utils/math/SafeMath.sol";
import "@openzeppelin/contracts/utils/Counters.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/token/ERC721/ERC721.sol";

// @author: wenbali.io

// ccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccc
// ccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccc
// ccccccccccccccccccccccccccccc:::;:::;:::ccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccc
// ccccccccccccccccccccccccccc;............,:ccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccc
// cccccccccccccccccccccccccc;............ .;ccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccc
// cccccccccccccccccccccccccc,..............':::::::::cccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccccc
// cccccccccccccccccccccccccc,..............';:::::::::;;;;;;;;::::ccccccccccccccccccccccccccccccccccccccccccccccccccccccc
// cccccccccccccccccccccccccc;. ........';coodddddddddooollccc:::::;;;;;;:cccccccccccccccccccccccccccccccccccccccccccccccc
// cccccccccccccccccccccccccc:'........cdddddddddddddddddddddddddddollcc::;;;;;::ccccccccccccccccccccccccccccccccccccccccc
// ccccccccccccccccccccccccccc:;'.....,oddddddddddddddddddddddddddddddddddoolc::;;;;::cccccccccccccccccccccccccccccccccccc
// ccccccccccccccccccccccccccccccc::::;,coddddddddddddddddddddddddddddddddddddddolc:;;;;:ccccccccccccccccccccccccccccccccc
// cccccccccccccccccccccccccccccccccc;,;clodddddddddddddddddddddddddddddddddddddddddolc:;;;::ccccccccccccccccccccccccccccc
// cccccccccccccccccccccccccccccccc:,,:llloddddddddddddddddddddddddddooolcc::loddooolcc::;,'',:ccccccccccccccccccccccccccc
// cccccccccccccccccccccccccccccc:;;:llllloddddddddddddddddooolc:::;,'........',''.............';:cccccccccccccccccccccccc
// cccccccccccccccccccccccccccc:;;:llllcc:clolclooolcc::;,,''....................................,cccccccccccccccccccccccc
// cccccccccccccccccccccccccc:;;;::;,'..........''................................................,:cccccccccccccccccccccc
// cccccccccccccccccccccccc;'..'....................................................................,:cccccccccccccccccccc
// ccccccccccccccccccccc:;...........................................................................':ccccccccccccccccccc
// cccccccccccccccccccc:'.............................................................................,ccccccccccccccccccc
// cccccccccccccccccccc,. .........................................................................'..':cccccccccccccccccc
// ccccccccccccccccccc;.....................................................................';cldkOKOc,:cccccccccccccccccc
// cccccccccccccccccc;...................................................................:dOKXNWWWWNN0c;cccccccccccccccccc
// ccccccccccccccccc,..............................................'.';:ccloddc,'..,cdkxocdKNNWWWWWWNNO:;ccccccccccccccccc
// cccccccccccccccc;.............'',;:ccllc;..........'',,;::;,..,:occk0000000xxkkxO0000OxllkXNWWWWWWNXx::cccccccccccccccc
// ccccccccccccccc:.......,:coxk0KKXNNNNNWNOoc,,codxkkkOO00000koodxkxxO0000000000000000000kocxKNWWWWWNX0l;:ccccccccccccccc
// ccccccccccccccc,.';cdk0XNWWWWWWWWWWWWWWWNXxlxO000000000000000000000000000000000000000000OdcdKNWWWWNNO:':ccccccccccccccc
// ccccccccccccccc;lOKXNWWWWWWWWWWWWWWWWWWNXkldO000000Oxddxk000000000000000000OkxdxkO0000000OdcdXNWWWWNXd;:ccccccccccccccc
// cccccccccccccc:lOXXNNWWWWWWWWWWWWWWWWWNN0ook0000Od:;;;;,',lk000000OO00000xc,',;;;;:d000000OdcxNWWWWWNKo;:cccccccccccccc
// ccccccccccccc::xXXNNWWWWWWWWWWWWWWWWWWWNxlxO000Ol':xOOOkdc,lO000KOdx0000Oc,cdkO0Od:,o000000OllKWWWWWWN0l;:ccccccccccccc
// ccccccccccccc:l0XXXNNWWWWWWWWWWWWWWWWWNKolk00000xxOkdddxxxxO00000kox00000OxxxxdddOOxx00000Ox::OWWWWWWNNOc;ccccccccccccc
// ccccccccccccc:dXXXXNNWWWWWWWWWWWWWWWWWNOloO0000000xlodxdddodO0K00klx0000Ododxdddook0000000Ol;dXWWWWWWWNXx;:cccccccccccc
// cccccccccccc::lkXXXNWWWWWWWWWWWWWWWWWWNkldO000000OodxddllddlxKK00kld0000xldddolokdo0000000kldXWWWWWWWWWNKo;:ccccccccccc
// cccccccccccc:,,xXXXNWWWWWWWWWWWWWWWWWWNkldO0000000doxdoooxolkKK00Ood0000kloddooxkox0000000xo0WWWWWWWWWWNNOc;ccccccccccc
// ccccccccccccc;cOXXXNWWWWWWWWWWWWWWWWWWNOcldkO000000xddooollx0000K0ooO0000xlloooddx00000000ddXWWWWWWWWWWWNXo;:cccccccccc
// ccccccccccccc;l0XXXNWWWWWWWWWWWWWWWWWWNKo;;lO0000000OxdddkOO000000dlk0000OkxdddkO00000000xoONWWWWWWWWWWWNNOc;cccccccccc
// ccccccccccccc;l0XXXNWWWWWWWWWWWWWWWWWWWNX0kookkkOO0000000000000000kld00000000000000OkxxdocxXWWWWWWWWWWWWWNXd;:ccccccccc
// ccccccccccccc;cOXXXNWWWWWWWWWWWWWWWWWWWWNNN0ocoooddxkO000000000000OooO0000000000OkxdooooclKNWWWWWWWWWWWWWNN0c;ccccccccc
// ccccccccccccc:cOXXNNWWWWWWWWWWWWWWWWWWWWWWWNKocoooooodxO00000000000xlx00000000Okdoooooc:lONWWWWWWWWWWWWWWWNXx;:cccccccc
// ccccccccccccc::kXXNNWWWWWNXXWWWWWWWWWWWWWWWWNKocooooooodxO0000000000olk000000kdoooool:,:ONWWWWWWWWWWWWWWWWNN0c;cccccccc
// ccccccccccccc:;dXXNNWWWWWXkONNWWWWWWWWWWWWWWWNKoclclooooodx000000000kldO000OxdoooooclkOKNWWWWWWWWWWWWWWWWWWNKo;:ccccccc
// cccccccccccccc;oKXXNWWWWW0x0XNNWWWWWWWWWWWWWWWNKd;,:cloooooxO00000000xldO0OxdooooclxKNNNWWWWWWWWWWWWWWWWWWWNXk::ccccccc
// cccccccccccccc;l0XXNWWWWNkxKXXXNWWWWWWWWNXNWWWWWXkx0kolcloodxO00000000xldOxdoolclxKNWWWWWWWWWWWWWWWWWWWWWWWNNOc;ccccccc
// cccccccccccccc;cOXXNWWWWKxxO0KXXNNWWWWWNOxKWWWWWWWWWWN0dc,;;:oO00000000xlllccldOXNWWWWWWWWWN0KNWWWWWWWWWWWWNNKl;ccccccc
// cccccccccccccc::kXXNWWWW0d:,l0XXNNWWX0kkoox0NWWWWWWNKkxxxxkkdoxddk000000x::cloxkKNWWWWWWWWN0olxOKNWWNNNWWWWWNKo;ccccccc
// cccccccccccccc::kXXNWWWWNX0dd0XXNWWKxkxlco:lKWWWWNOddkKNWWWWNK00ocoxkOOxdoONNX0kxdkKNWWWWNOcccldxxKNXOKWWWWWNXd;:cccccc
// cccccccccccccc::kXXNWWWWWWWOxKXXNWXxO0olcl:oXWWWKdoONWWWWWWWWNXOlcdxdl:oOKNWWWWWNKxokXWWWNd;lc;dOkd0NkkNWWWNNXk::cccccc
// cccccccccccccc::kXXNWWWWWWNkxKXXNWOdKOd00kOXNWNOlxXWWWWWWWWN0occxXWWNXxokXWWWWWWWWNKdo0NWWKxddOxxKddX0dONWWNXX0c;cccccc
// cccccccccccccc;cOXXNWWWWWWNkxXXXXN0d00oONWWWWKxlkNWWWWWWWN0ocdkKNNNWWWNOdokXWWWWWWWWXxlONWWWNNNxxXdoOo;oXWNXX0kl;cccccc
// cccccccccccccc;c0XXNNWWWWWNxkXXXXNXkdKOox0KOxoxKNWWWWWNKkl:cxkkxxxkOOOxddoccdKNWWWWWWNOodOXWWNko00olc;lOXNNXx;'';cccccc
// cccccccccccccc;c0XXXNNWWWWNkkXXXXXNXkokOkxxxOXNWWWNX0dlccclkX0dokXKxokK0dO0c':lxKNWWWWWXOddxxdd0OldOdd0XXNNNx,,;:cccccc
// cccccccccccccc;l0XXXXNNWWWNkxXXXXXXNN0doxk0KXXK0kxdol;cOXxokOo:lkOkooxkdoxkooxlcoddkKXNWWNXK0OkdokXKxOXXXNNWKl;cccccccc
// cccccccccccccc;oKXXXXXNNWWNkxXXXXXXXNWNKkxdddddddxOKXKOOOoo0Ol;dKKxlk0kod0OdoxOXNKkxddxxxxxxdddkKNWXxkXXXXNNNd;:ccccccc
// ccccccccccccc::dXXXXXXNWWWNkxKXXXXXXNNWWWWNNNNNNNWWWWWWN0l:c:;;:clc:cllc:cclokNWWWWWNXK0OOO0KNNWWWWXkkXXXXXNWO::ccccccc
// ccccccccccccc:;ldokXXNNWWWWOdKXXXXXXXNNWWWWWWWWWWWWWWWWWKdx0OkkxxxxxxxkkkO0KkkXWWWWWWWWWWWWWWWWWWWWXxkXXXXXNWKc;ccccccc
// ccccccccccccc:;'',dXXNNWWWW0d0XXXXXXXXNNWWWWWWWWWWWWWWWWXxkNWWWWWWWWWWWWWWWNkkXWWWWWWWWWWWWWWWWWWWWXxxXXXNNNWXo;ccccccc
// ccccccccccccccc:;:kXXNNWWWWKxookXXXXXXNNWWWWWWWWWWWWWWWWXxx0XWWWWWWWWWWWWWWNkkNWWWWWWWWWWWWWWWWWWWWXxxXXXNNWWNd;:cccccc
// cccccccccccccccc;l0XXNWWWWWNklcdKXXXXXNNWWWWWWWWWWWWWWWWNk:cONNWWWWWWWWWWN0dokNWWWWWWWWWWWWWWWWWWWWKxkXXXNNWWNk::cccccc
// ccccccccccccccc::xXXXNNWWWWWNXOd0XXXXXXNNWWWWWWWWWWWWWWWWXOdxNWWWWWWWWWWWNxokKWWWWWWWWWWWWWWWWWWWWW0xOXXXXNWWWOc:cccccc
// cccccccccccccc:;oKXXXNWNWWWWWWXxxXXXXXXXNNWWWWWWWWWWWWWWWWNkdKWWWWWWWWWWWXdkNWWWWWWWWWWWWWWWWWWWW0xdd0XXXXNWWW0c;cccccc
// cccccccccccccc;:OXXXNNWWWWWWWWWKdOXXXXXXXNNWWWWWWWWWWWWWWWW0okXNWWWWWWWWWKdONWWWWWWWWWWWWWWWWWWWNklldKXXXXNWWWXl;cccccc
// cccccccccccccc;lKXXXNNWWWWWWWWWNOdOXXXXXXXNNWWWWWWWWWWWWWWWNxokKWWWWWWWWWOd0WWWWWWWWWWWWWWWWWWWWKxOKKXXXXXNWWWXo;cccccc
// ccccccccccccc:;oXXXXNNWWWWWWWWWWKlc0XXXXXXXXNNWWWWWWWWWWWWWWKdcxNWWWWWWWNkdXWWWWWWWWWWWWWWWWWWWNkxKXXXXXXXNWWWNd;:ccccc
// ccccccccccccc:;dXXXXXNNWWWWWWWNOlcco0XXXXXXXXNNWWWWWWWWWWWWWNOooONWWWWWWXxkNWWWWWWWWWWWWWWWWWWW0dOXXXXXXXXNWWWNx;:ccccc
// ccccccccccccc:;dXXXXXXNNWWWNXOo:okklo0XXXXXXXXXNNWWWWWWWWWWWWNXkdKNWWWWW0x0WWWWWWWWWWWWWWWWWWWXo:kXXXXXXXXNWWWNx;:ccccc
// ccccccccccccc:;oKXXXXXXXKOdl:.'oOOOklo0XXXXXXXXXXNNWWWWWWWWWWWWNkdKWWWWXxkNWWWWWWWWWWWWWWWWWWNxllcdKXXXXXNWWWWWk::ccccc
// cccccccccccccc;l0XXX0kdl:;;;',dOOOOOkloOkkKKKXXXXXNNWWWWWWWWWWWWXkdxkKXxdKWWWWWWWWWWWWWWWWWWNklxOd:oKXXXXNWWWWNx;:ccccc
// cccccccccccccc::oxoc:;;::::,'oOOOOOOOkolc:lcl0XXXXXNWWWWWWWWWWNWWN0xdddxKNWWWWWWWWWWWWWWWNWNklxOOOd:l0XXXNNWWWNx;:ccccc
// ccccccccccccc:;'',;:::::::;'cOOOOOOOOOOkkxlolo0XXXXNWWWWWWWWWWWWWWWWNKKXWWWWWWWWWWWWWWXOddxdlxOOOOOd:lKXXXNWWWNd;:ccccc
// cccccccccccc:,',;;;;;;::::';xOOOOOOOOOOOOOOOxlo0XXXNNNWWWWWWWWWWWWWWWWWWWWWWWWWWWWWWWKo;coodkOOOOOOOo;oXXXNNWWXl;cccccc
// ccccccccccc;',::;,,,,,',:,,oOOOOOOOOOOOOOOOOOxlo0XXXXNNNWWWWWWWWWWWWWWWWWWWWWWWWWWWWXdlxkOOOOOOOOOOOOc;kXXNNWWOc:cccccc
// cccccccccc:',:::::::::;;;':kOOOOOOOOOOOOOOOOOOxco0XXXXXNNNWWWWWWWWWWWWWWWWWWWWWWWWWXdokOOOOOOOOOOOOOOx;,xXXNWNx;:cccccc
// cccccccccc;';:::::::::::;'cOOOOOOOOOOOOOOOOOOOOkllOXXXXXXNNNWWWWWWWWWWWWWWWWWWWWWWKdokOOOOOOOOOOOOOOOOc.'xXNWKo;ccccccc
// ccccccccc:',::::::::::::;'lOOOOOOOOOOOOOOOOOOOOOkocxKXXXXXXNNNWWWWWWWWWWWWWWWWWWN0ookOOOOOOOOOOOOOOOOOd'.:ONNOc;ccccccc
// ccccccccc;',::::::::::::;':kOOOOOOOOOOOOOOOOOOOOOOdco0K0KXXXXNWWWWWWWWWWWWWWWWWXkodOOOOOOOOOOOOOOOOOOkl..,oXXd;:ccccccc
// ccccccccc,';:::::::::::::,';cldxkkOOOOOOOOOOOOOOOOOklll:lOXXXNNNWWWWWWWWWWWNOOOdokOOOOOOOOOOOOOOOkxoc;..;,:kkc:cccccccc
// cccccccc:'':::::::::::ccc:;,'.'',,;;::loxkOOOOOOOOOOOxodo:o0XXXXNNWWWWWWWWKxcclxOOOOOOOOOOkxdlc:;,'..',;:;',::ccccccccc
// cccccccc:'':::::::::::ccc::::;;;,,,'''..',;ldkOOOOOOOOOOx;.:xKXXXNNWWWWWNklokOOOOOOOOkxoc;,'...'',;;;:::::,.;cccccccccc
// cccccccc:',::::::::::::ccc:::cc::::::::;;,'..,cxOkxkOOOOx;,::cdkXXK0XWNOo';kOOOOOOOkl;'..',;;;::::::::::::;',cccccccccc
// cccccccc;',::::::::::::cccc:::::::::::::::;;,'.';,',:ldOk:,ll:;:oxc,okoc:,ckOOkxxxc,..,,;::::::::::::::::::'':ccccccccc
// cccccccc;',:::::::::::ccccccc:::::::::::;;::;;;,',,,'.'okc,cooolc:::::clc,ckkd;'''..,,',,,,;;::::::::::::::,';ccccccccc
// cccccccc;';:::::::::ccccccccccc::::::::;',:::::::::::;':kl,coooooooooollc,:ko'.'',',,.'::'';;;:::::::::::::;';ccccccccc
// cccccccc,';:::::::::cccccccccccc:::::::;'',,:::::::::c,;xd,:oooooooooooll';kc.';;:'':'.,:,';:::::::::::::::;';ccccccccc
// cccccccc,';::::::::::cccccccc:::::::::::'..;:::::::::c;,dx;;looooooooolll',xl.';::;.';..,;'.;:::;,::::::::c;';ccccccccc
// cccccccc;';::::::::::ccccccccc::::::::::'.';:::::::::c;,ok;,looooooooooll',dl.';:::,.';..,:'.;:;'';::::cccc:',ccccccccc
// cccccccc;';::::::::::ccccccccc::::::::::'.';:::::::::c;,lk:,looooooolooll,'ol.';:;;;'.:;..,,';:,..;cccccccc:',ccccccccc
// cccccccc;';:::::::::::cccccc::c:::::::::,.,::::::::::::,lk:,colloooooolll;'oo.':::;;'';;..,;::c:..;cccccccc:',ccccccccc
// cccccccc;',:::::::::::cccccc::::::::::::,.,::::::::::c:,ckc'cooolllllllll;'lo'.;:::::;,,,;:::cc:'.:cccccccc;';ccccccccc
// cccccccc;',:::::::::::ccccccc::::::::::;'';:::::::::cc:,ckc'cooolllllllll:'lx,.;::::::::::::::c:..:cccccccc,':ccccccccc
// cccccccc:',:::::::::::cccccccc:::::::::;.';:::::::::cc:,ckc':llllllllllll:'cx;.;:::::::::::::cc;..:cccccccc,':ccccccccc

contract SecretSantaSociety is ERC721, Ownable {
    using SafeMath for uint256;
    using Strings for uint256;
    using Counters for Counters.Counter;
    Counters.Counter private _nextTokenId;
    Counters.Counter private _nextGiftedAmount;

    // Provenance - Artwork Sequence Established Beforehand and Untouched
    string public constant PROVENANCE_HASH =
        "ae7bef7dc7ffab5f1d74ad39232f62f2166369307e3f60809b34a5ec7eb53940";

    // Donation Wallet - secretsantasociety.eth
    // All outgoing transactions to be monitored for donations
    // see withdraw() function - Hardcoded 10%
    address public donationWallet = 0x27632f8E0c9951d9E9c97e7AeC18a85d2D5188dc;

    // Contract URI
    string private _contractURI;
    // Unrevealed URI
    string private _unrevealedURI;

    // Sale
    // actual supply qty is one less (gas savings in comparison operations)
    uint256 public constant NFT_SUPPLY = 5556; //actually 5555
    uint256 public constant MAX_TOKENS_PRESALE = 8; //actually 7
    uint256 public constant MAX_TOKENS_PUBLIC_SALE = 16; //actually 15
    uint256 public constant MINT_PRICE = 0.055 ether;

    // Dates
    uint256 public constant PRESALE_START_TIME = 1637524800; // 2:00 pm CST November 21th 2021
    uint256 public constant PRESALE_STOP_TIME = 1637784000; // 2:00 pm CST November 24th 2021
    uint256 public constant PUBLIC_SALE_START_TIME = 1637956800; // 2:00pm CST November 26th 2021

    // Start/pause sale
    bool public saleStarted; //defaults to false

    // array of nice listed addresses
    mapping(address => bool) public niceListedAddresses;
    // array of ipfs CIDs mapped to tokenIds
    mapping(uint256 => string) private _tokenUriList;
    // array of presale minters
    mapping(address => uint256) public mintedOnPresale;

    // Events
    event SaleStateFlipped(bool state);
    event PresaleMinted(address indexed _who, uint8 indexed _amount);
    event Minted(address indexed _who, uint8 indexed _amount);
    event GiftMinted(address recepient);
    event FundsWithdrawn(uint256 balance);
    event FallbackHit(address indexed _who, uint256 indexed _amount);

    constructor() ERC721("Secret Santa Society", "SSS") {
        // skip the 0; gas savings
        _nextTokenId.increment();
        _nextGiftedAmount.increment();
    }

    function contractURI() public view returns (string memory) {
        return _contractURI;
    }

    function totalSupply() public view returns (uint256) {
        return _nextTokenId.current() - 1; // total supply is one less than next id
    }

    function giftedAmount() public view returns (uint256) {
        return _nextGiftedAmount.current() - 1; // actual gifted is one less that next amount
    }

    function tokenURI(uint256 tokenId)
        public
        view
        virtual
        override
        returns (string memory)
    {
        require(_exists(tokenId), "Nonexistent token");
        if (!_hasCID(tokenId)) {
            return string(_unrevealedURI);
        } else {
            return string(_tokenUriList[tokenId]);
        }
    }

    // verify that the CID has been set for the requested token
    function _hasCID(uint256 tokenId) private view returns (bool) {
        return !(bytes(_tokenUriList[tokenId]).length == 0);
    }

    function presaleMint(uint8 amountToMint) public payable {
        require(saleStarted == true, "Sale not active");
        require(block.timestamp > PRESALE_START_TIME, "Presale not started");
        require(block.timestamp < PRESALE_STOP_TIME, "Presale ended");
        require(niceListedAddresses[msg.sender], "Presale not listed");
        require(MINT_PRICE.mul(amountToMint) == msg.value, "Incorrect amount");
        require(
            mintedOnPresale[msg.sender] + amountToMint < MAX_TOKENS_PRESALE,
            "Presale too many"
        );
        require(
            amountToMint > 0 && amountToMint < MAX_TOKENS_PRESALE,
            "Presale 1-7 Santas"
        );

        mintedOnPresale[msg.sender] += amountToMint;
        for (uint256 i = 0; i < amountToMint; i++) {
            _safeMint(msg.sender, _nextTokenId.current());
            _nextTokenId.increment();
        }
        emit PresaleMinted(msg.sender, amountToMint);
    }

    function mint(uint8 amountToMint) public payable {
        require(
            saleStarted && block.timestamp > PUBLIC_SALE_START_TIME,
            "Sale not active"
        );
        require(totalSupply() < NFT_SUPPLY, "Exceeds max supply");
        require(totalSupply() + amountToMint < NFT_SUPPLY, "Out of tokens");
        require(
            amountToMint > 0 && amountToMint < MAX_TOKENS_PUBLIC_SALE,
            "Mint: 1-15 per tx"
        );
        require(MINT_PRICE.mul(amountToMint) == msg.value, "Incorrect amount");

        for (uint256 i = 0; i < amountToMint; i++) {
            _safeMint(msg.sender, _nextTokenId.current());
            _nextTokenId.increment();
        }
        emit Minted(msg.sender, amountToMint);
    }

    /*
    Owner functions
    */

    // start/stop the sell
    function flipSaleState() external onlyOwner {
        saleStarted = !saleStarted;
        emit SaleStateFlipped(saleStarted);
    }

    // Updates the contract uri; just in case
    function setContractUri(string memory contractUri) external onlyOwner {
        _contractURI = contractUri;
    }

    // Updates the reveal uri; just in case
    function setUnrevealedUri(string memory unrevealedUri) external onlyOwner {
        _unrevealedURI = unrevealedUri;
    }

    // MFC!
    function giftMint(address[] calldata recipients) external onlyOwner {
        require(
            totalSupply() + recipients.length < NFT_SUPPLY,
            "Gifting exceeds max supply"
        );
        require(recipients.length > 0, "Recipients > 0");
        for (uint256 i = 0; i < recipients.length; i++) {
            _safeMint(recipients[i], _nextTokenId.current());
            _nextGiftedAmount.increment();
            _nextTokenId.increment();
            emit GiftMinted(recipients[i]);
        }
    }

    function batchTokenUriList(
        uint256 startingTokenId,
        string[] memory tokenUriList
    ) external onlyOwner {
        uint256 lastToken = startingTokenId + tokenUriList.length - 1;
        require(tokenUriList.length > 0, "List > 0");
        require(startingTokenId > 0 && _exists(lastToken), "Out of range");
        uint256 count;
        for (uint256 i = startingTokenId; i < lastToken + 1; i++) {
            _tokenUriList[i] = tokenUriList[count++];
        }
        delete lastToken;
        delete count;
    }

    function setTokenUri(uint256 tokenId, string memory tokenUri)
        external
        onlyOwner
    {
        require(_exists(tokenId), "Out of range");
        _tokenUriList[tokenId] = tokenUri;
    }

    // good boys and girls live here
    function batchNicelist(address[] memory niceList) external onlyOwner {
        for (uint256 i = 0; i < niceList.length; i++) {
            niceListedAddresses[niceList[i]] = true;
        }
    }

    // Owner withdraw and fund Donation Wallet
    function withdraw() external onlyOwner {
        uint256 balance = address(this).balance;
        Address.sendValue(
            payable(donationWallet),
            (address(this).balance * 10) / 100
        );
        Address.sendValue(payable(msg.sender), address(this).balance);
        emit FundsWithdrawn(balance);
    }

    // A fallback function in case someone sends ETH to the contract
    receive() external payable {
        emit FallbackHit(msg.sender, msg.value);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        assembly {
            size := extcodesize(account)
        }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

// CAUTION
// This version of SafeMath should only be used with Solidity 0.8 or later,
// because it relies on the compiler's built in overflow checks.

/**
 * @dev Wrappers over Solidity's arithmetic operations.
 *
 * NOTE: `SafeMath` is no longer needed starting with Solidity 0.8. The compiler
 * now has built in overflow checking.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            uint256 c = a + b;
            if (c < a) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the substraction of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b > a) return (false, 0);
            return (true, a - b);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
            // benefit is lost if 'b' is also tested.
            // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
            if (a == 0) return (true, 0);
            uint256 c = a * b;
            if (c / a != b) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a / b);
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a % b);
        }
    }

    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        return a + b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return a - b;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        return a * b;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator.
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return a % b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {trySub}.
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        unchecked {
            require(b <= a, errorMessage);
            return a - b;
        }
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a / b;
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting with custom message when dividing by zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryMod}.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a % b;
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @title Counters
 * @author Matt Condon (@shrugs)
 * @dev Provides counters that can only be incremented, decremented or reset. This can be used e.g. to track the number
 * of elements in a mapping, issuing ERC721 ids, or counting request ids.
 *
 * Include with `using Counters for Counters.Counter;`
 */
library Counters {
    struct Counter {
        // This variable should never be directly accessed by users of the library: interactions must be restricted to
        // the library's function. As of Solidity v0.5.2, this cannot be enforced, though there is a proposal to add
        // this feature: see https://github.com/ethereum/solidity/issues/4637
        uint256 _value; // default: 0
    }

    function current(Counter storage counter) internal view returns (uint256) {
        return counter._value;
    }

    function increment(Counter storage counter) internal {
        unchecked {
            counter._value += 1;
        }
    }

    function decrement(Counter storage counter) internal {
        uint256 value = counter._value;
        require(value > 0, "Counter: decrement overflow");
        unchecked {
            counter._value = value - 1;
        }
    }

    function reset(Counter storage counter) internal {
        counter._value = 0;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _setOwner(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _setOwner(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _setOwner(newOwner);
    }

    function _setOwner(address newOwner) private {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "./IERC721.sol";
import "./IERC721Receiver.sol";
import "./extensions/IERC721Metadata.sol";
import "../../utils/Address.sol";
import "../../utils/Context.sol";
import "../../utils/Strings.sol";
import "../../utils/introspection/ERC165.sol";

/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension, but not including the Enumerable extension, which is available separately as
 * {ERC721Enumerable}.
 */
contract ERC721 is Context, ERC165, IERC721, IERC721Metadata {
    using Address for address;
    using Strings for uint256;

    // Token name
    string private _name;

    // Token symbol
    string private _symbol;

    // Mapping from token ID to owner address
    mapping(uint256 => address) private _owners;

    // Mapping owner address to token count
    mapping(address => uint256) private _balances;

    // Mapping from token ID to approved address
    mapping(uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
        return
            interfaceId == type(IERC721).interfaceId ||
            interfaceId == type(IERC721Metadata).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner) public view virtual override returns (uint256) {
        require(owner != address(0), "ERC721: balance query for the zero address");
        return _balances[owner];
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId) public view virtual override returns (address) {
        address owner = _owners[tokenId];
        require(owner != address(0), "ERC721: owner query for nonexistent token");
        return owner;
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
        require(_exists(tokenId), "ERC721Metadata: URI query for nonexistent token");

        string memory baseURI = _baseURI();
        return bytes(baseURI).length > 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : "";
    }

    /**
     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
     * by default, can be overriden in child contracts.
     */
    function _baseURI() internal view virtual returns (string memory) {
        return "";
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = ERC721.ownerOf(tokenId);
        require(to != owner, "ERC721: approval to current owner");

        require(
            _msgSender() == owner || isApprovedForAll(owner, _msgSender()),
            "ERC721: approve caller is not owner nor approved for all"
        );

        _approve(to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId) public view virtual override returns (address) {
        require(_exists(tokenId), "ERC721: approved query for nonexistent token");

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        require(operator != _msgSender(), "ERC721: approve to caller");

        _operatorApprovals[_msgSender()][operator] = approved;
        emit ApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");

        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) public virtual override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");
        _safeTransfer(from, to, tokenId, _data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * `_data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _transfer(from, to, tokenId);
        require(_checkOnERC721Received(from, to, tokenId, _data), "ERC721: transfer to non ERC721Receiver implementer");
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     * and stop existing when they are burned (`_burn`).
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool) {
        return _owners[tokenId] != address(0);
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _isApprovedOrOwner(address spender, uint256 tokenId) internal view virtual returns (bool) {
        require(_exists(tokenId), "ERC721: operator query for nonexistent token");
        address owner = ERC721.ownerOf(tokenId);
        return (spender == owner || getApproved(tokenId) == spender || isApprovedForAll(owner, spender));
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to`.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal virtual {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _mint(to, tokenId);
        require(
            _checkOnERC721Received(address(0), to, tokenId, _data),
            "ERC721: transfer to non ERC721Receiver implementer"
        );
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal virtual {
        require(to != address(0), "ERC721: mint to the zero address");
        require(!_exists(tokenId), "ERC721: token already minted");

        _beforeTokenTransfer(address(0), to, tokenId);

        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(address(0), to, tokenId);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal virtual {
        address owner = ERC721.ownerOf(tokenId);

        _beforeTokenTransfer(owner, address(0), tokenId);

        // Clear approvals
        _approve(address(0), tokenId);

        _balances[owner] -= 1;
        delete _owners[tokenId];

        emit Transfer(owner, address(0), tokenId);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {
        require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer of token that is not own");
        require(to != address(0), "ERC721: transfer to the zero address");

        _beforeTokenTransfer(from, to, tokenId);

        // Clear approvals from the previous owner
        _approve(address(0), tokenId);

        _balances[from] -= 1;
        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(from, to, tokenId);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * Emits a {Approval} event.
     */
    function _approve(address to, uint256 tokenId) internal virtual {
        _tokenApprovals[tokenId] = to;
        emit Approval(ERC721.ownerOf(tokenId), to, tokenId);
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
     * The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param _data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkOnERC721Received(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) private returns (bool) {
        if (to.isContract()) {
            try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, _data) returns (bytes4 retval) {
                return retval == IERC721Receiver.onERC721Received.selector;
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    revert("ERC721: transfer to non ERC721Receiver implementer");
                } else {
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        } else {
            return true;
        }
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting
     * and burning.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s `tokenId` will be
     * transferred to `to`.
     * - When `from` is zero, `tokenId` will be minted for `to`.
     * - When `to` is zero, ``from``'s `tokenId` will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {}
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol

        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        if (value == 0) {
            return "0x00";
        }
        uint256 temp = value;
        uint256 length = 0;
        while (temp != 0) {
            length++;
            temp >>= 8;
        }
        return toHexString(value, length);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _HEX_SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}